$!			UTL.COM
$!
$	Verify_at_Start='F$VERIFY(0)'
$	TESTFILE SYS$SYSDISK:[SYSUTL]'P1'.TSK
$	IF $STATUS .NE. 1 THEN GOTO Native_Mode
$	TEMP:==MC SYS$SYSDISK:[SYSUTL]'P1'.TSK
$	GOTO Do_It
$Native_Mode:
$	TESTFILE SYS$SYSDISK:[SYSUTL]'P1'.EXE
$	IF $STATUS .NE. 1 THEN GOTO No_Such_Task
$	TEMP:==$SYS$SYSDISK:[SYSUTL]'P1'
$Do_It:
$	ASSIGN/USER SYS$COMMAND SYS$INPUT
$	TEMP 'P2' 'P3' 'P4' 'P5' 'P6' 'P7' 'P8' 'P9'
$	DELETE/SYMBOL/GLOBAL TEMP
$	IF Verify_at_Start THEN SET VERIFY
$	EXIT
$No_Such_Task:
$	WRITE SYS$OUTPUT "UTL -- Neither ''P1'.TSK nor ''P1'.EXE exist on [SYSUTL]
$	IF Verify_at_Start THEN SET VERIFY
$	EXIT
$!
$!  File Name:	UTL.COM
$!  Author:	James G. Downward
$!  Date:	03-March-1982
$!  Function:
$!		This command procedure is used to simplify the activation of
$!		the non-DEC utility tasks on [SYSUTL] in much the same way
$!		that the MC[r] command is used to activate tasks on [SYSEXE].
$!		The syntax is
$!				UTL TSKNAM parm...parm...parm...
$!
$!		where the various parameters are separated by spaces.  
$!		UTL.COM is designed to be used as a foreign command, ie
$!
$!				UTL:==@[SYSMGR.CMDFIL]UTL
$!
$!  Modified:
$!		04-April-1982	Jim Downward
$!				VMS V2.5 Update changed parsing for foreign
$!				compatability mode programs to require that
$!				for commands not on [SYSEXE] we had to change 
$!				the activation from $<filspec> to MC <filspec>
$!				in order to get command line to pass.
$!