!									!
!	GUESS.TEC							!
!									!
!	GUESS the number game						!
!									!
!									!
!	Set protection code to <104> if execution by typing RUN GUESS	!
!	is desired, otherwise execute by typing MUNG GUESS		!
!									!
!	Written 19-Feb-82	Jeff Corbett				!
!				Student Programer			!
!				Erskine College				!
!				Due West, South Carolina		!
!									!
!				Bug reports and comments to:		!
!									!
!				1510 Carteret Street			!
!				Columbia, SC   29203			!
!									!
!	edited   6-May-82	Jeff Corbett				!


!	Define Macro (MI) to take an input string and leave in buffer	!
@^UI%
< ^T@I// (127-(-1A))"E -D  Z"> -D 8^T 32^T 8^T '
 | (13-(-1A))"E -D ^T 0;' ' >
%
!	Clear input buffer						!
6<^T> 

!	Get a time based number for Random seed				!
(^H+^B)US 

!Generate Random Number!
(( QS*18733+6925 )& 32767 )US 

(QS/327)UR 

@^A/
I'm thinking of a number between 1 and 100. You try to guess it.
/

!START!
JHK 
@^A/
Your guess? /
MI
0L \UA !User's guess in Q-reg A!
HK

@^A/That number is /

(QA-QR)"> @^A/too high.
/ @O/START/'
(QA-QR)"< @^A/too low.
/ @O/START/'
@^A/right!  You got it!
/ '

@^A/
Do you wish to play again <N>? /
MI

0L 0AUA HK (QA-96)"> (QA-32)UA ' (QA-89)"E @^A\
\ @O/Generate Random Number/ '
HKEX