Kermit Script Files: (PART 1 of 4)

This is a tutorial on MS-DOS Kermit scripts.  A script is a file containing
Kermit commands to be executed.  This script feature applies to MS-DOS
Kermit version 2.30 and above.  Versions prior to this release may or may
not have all of the functions described in this series of messages.  MS-DOS
Kermit, version 2.30, may be copied from the terminal room located at 251
Mudd or may be purchased from the User Services Business Office at 321 SIA.

Scripts may contain any Kermit command, just as a TAKE file in Kermit
terminology, but may also include other special commands such as INPUT,
OUTPUT, PAUSE, ECHO, and CLEAR to automatically detect and respond to
information flowing though the serial port.  These actions would otherwise
be performed by the user during CONNECT.  The login sequence of a host
computer is a classic example.

 INPUT:  tells Kermit to look for certain characters from the other computer.
 OUTPUT: tells Kermit to send the given characters to the other computer.
 ECHO:   displays the given string on your screen.
 PAUSE:  tells Kermit to wait a specified number of seconds before continuing.
 CLEAR:  empties the buffers of the serial port to forget earlier material.

For complete details about scripts, see the MS-DOS Kermit User Guide.

Below are some examples of common script uses.  There are some general
settings which you will probably want to use all the time so these commands
have been placed in the file called GENERAL.SCR below.

==============================CUT HERE==============================

; GENERAL.SCR
;
COMMENT Kermit script with general settings.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; Add this section onto the top of any of your login script files --
; PACX.SCR, ROLM.SCR or DIAL.SCR.
; If no timeout period is given, the default is 1 second
;
set terminal VT102        ; Set terminal type
set input echo on         ; Echo responses
set input timeout quit    ; Stop if no response after the provided time period
set speed 9600            ; Can change to 4800, etc.
set parity none           ; Do not use any parity
set handshake none        ; Do not use any hanshaking characters
set flow xon              ; Use XON/XOFF flow control 
set local off             ; Do not use local echo
;
; ADD DIAL.SCR HERE IF DIALING UP.
; THEN ADD PACX.SCR or ROLM.SCR.
;
COMMENT - End Kermit General Settings Script

==============================CUT HERE==============================

There are three common ways to connect to any computer:

1. Using the LDS-125 PACX boxes we currently have on campus at Columbia
   University or the ROLM data phones which will soon replace them.

2. Using a modem to dial from one computer to another.
   (* Note: A user must still go through the PACX or ROLM switch even 
            when dialing up in order to connect to CUCCA's host systems).

3. Using a direct line (cable) which runs from one computer to another.
   (* Note : A script file here would only need to set the speed or baud rate)


Always use:                      GENERAL.SCR
                                      |
                                      |
Use only if dialing:               DIAL.SCR         Omit this if connected
                                  /   |    \        directly to the PACX.
                                 /    |     \
Use if going thru a             /     |      \
switch (e.g. when           PACX.SCR  |  ROLM.SCR   Omit this step for 
connecting to the               \     |      /      hardwired host connections
CUCCA host systems).             \    |     /       or direct host dialup.
                                  \   |    /
Script for logging in             CUNIX.SCR         Or CU20B.SCR, CUVMA.SCR,
to a particular system.                             CLIO.SCR, etc.


Suppose you usually use the LDS-125 PACX box to connect to one of the many
computers on campus.  Instead of always typing the same commands
interactively, you may want to use the following script called PACX.SCR:

==============================CUT HERE==============================

; PACX.SCR
;
COMMENT Kermit script for connecting to CU systems thru PACX
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For use with the CUCCA mainframe systems connected via PACX lines.
; Add this section to the beginning of any of your login script files 
; (CUNIXC.SCR, etc.) AFTER your general script settings file (GENERAL.SCR).
;
echo Make sure your PACX box is turned on and ready\13
echo Type carriage return when ready...
output @con
pause 2			  ; Wait 2 secs
output \13                ; Give a CR (carriage return) (\13 = ASCII CR)
input 10 =>               ; Expect to see PACX prompt " => " within 10 seconds
pause 1                   ; Wait 1 second
;
; ADD CU20.SCR, CUVM.SCR, SIM.SCR, CLIO.SCR, or CUNIXC.SCR HERE.
;
COMMENT - End Kermit PACX Settings Script

==============================CUT HERE==============================

Then you could add a script which actually connected you to a specific
computer.  For example, suppose we usually connected to CUNIXC through a PACX
box.  Then we could run the GENERAL.SCR, followed by the PACX.SCR, followed
by the CUNIXC.SCR below:

==============================CUT HERE==============================

; CUNIXC.SCR
;
COMMENT Kermit script for connecting to CU CUNIXC system.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For use with the CUCCA's CUNIXC system.
; Add to the bottom of either PACX.SCR or ROLM.SCR.
;
output cunixc\13            ; Type cunixc and a carrige return (ASCII 13)
;output cunixa\13           ; Change to cunixa or any other UNIX system
pause 1                     ; Wait 1 second
input 10 login:             ; Expect to see CUNIXC's login prompt
output USERNAME\13          ; Type username (replace with yours) & CR
set input echo off          ; Privacy, please
input word:                 ; Expect to see password: (abbrev.)
echo \13Type your password: ; Make our own prompt.
output @con                 ; Type in password at your console
output \13                  ; Add a real carriage return
set input echo on	    ; Back to normal viewing
connect                     ; Connect to system
;
COMMENT - End of CUNIXC Script

==============================CUT HERE==============================

Notice the @con command in the script example above.  It is here that you
type your password to the console.  You could replace the @con with your
actual password in the script but this is not a good idea for security
reasons.  Anyone who ran your script would be able to login to your computer
account, or at least look at your script file to see your password.

How do you actually run these scripts?  You insert the MS-DOS Kermit 2.30
diskette in your floppy disk drive (or put the KERMIT.EXE file on your hard
disk) and type KERMIT.  The script files must be on this disk as well.  At 
the KERMIT-MS> prompt, you type TAKE <script filename>.

Example:

   A> KERMIT

   MS-KERMIT> TAKE GENERAL.SCR

   MS-KERMIT> TAKE PACX.SCR

   MS-KERMIT> TAKE CUNIXC.SCR

Yes, you can put ALL the commands in the three script files above into one
single file and say TAKE <filename> only one time.  The reason the single
file has been broken into three parts is because most users do not ALWAYS
want to use a PACX box.  Sometimes a modem or a direct line is used instead.
And users may even use other computers besides CUNIXC, such as CUVM, VMS,
CLIO or even the DEC-20.  With the separate files above, it is easy to
substitute PACX.SCR with something called ROLM.SCR and CUNIXC.SCR with
CUVM.SCR, as we will see in the next message of this script tutorial series.

------------------------------

Kermit Script Files: (PART 2 of 4)

This is the second part of the short tutorial on MS-DOS Kermit scripts.
The last message gave an example of a general script, which users will
probably always want to add to the beginning of their script files.

Following was an example of a script to connect a computer through the
LDS-125 Gandalf PACX box.  Users may sometimes use this method, but may also
want to connect to another computer using a modem.  The script below will
automatically do what a user would do interactively when connecting to
another computer using a Hayes or Hayes compatible modem.  You could write a
similar script for use with a modem that used a different dialing language.

* Note - CUCCA systems currently require that users go through the PACX box
         even after a dial-up connection is established.
         (You may, however, be able to dial directly into a departmental
         computer without going through the PACX box.)

==============================CUT HERE==============================

; DIAL.SCR
;
COMMENT Kermit script for dialing through a Hayes or compatible modem.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For use with the Hayes or compatible modem.
; Add this section onto any of your login script files (CUNIXC.SCR, etc.)
; AFTER your general script settings file (GENERAL.SCR).
;
clear                     ; Flush serial port buffers.
set speed 1200            ; (or 2400 if you have a 2400 bps modem)
output AT\13              ; Wakeup modem (AT, carriage return)
input OK                  ; It should say "OK".
pause                     ; Now pause a second.
output ATDT 2808050\13    ; Dial the phone (PACX number).
input 30 CONNECT          ; Wait for connect message.
pause 2                   ; Allow time for PACX to wake up.
;
; FOR CUCCA SYSTEMS YOU NEED TO ADD PACX.SCR HERE TO CONNECT.
; ADD CU20.SCR, CUVM.SCR, SIM.SCR, CLIO.SCR or CUNIXC.SCR AFTER THAT.
;
COMMENT - End of Hayes or compatible Modem Script

==============================CUT HERE==============================

Other users may also have direct cable connections from an IBM PC to another
computer.  In that case you need only set the speed or baud rate before
connection establishment.  This is already done in GENERAL.SCR.

Eventually, the PACX will be replaced by the new ROLM CBX and you will want
to have a script to connect this way also.  The Rolm dialog is similar to
the PACX dialog, except the PACX prompts you with "Enter node name =>" and
you type the name of the computer, whereas the Rolm prompts you with "CALL,
DISPLAY OR MODIFY?" and you type "CALL" followed by the name of the
computer.  You can replace your PACX.SCR with the ROLM.SCR file below.

==============================CUT HERE==============================

; ROLM.SCR
;
COMMENT Kermit script for connecting to CU systems thru the ROLM switch.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For use with the CUCCA mainframe systems connected via ROLM lines.
; Add this section to the beginning of any of your login script files 
; (CUNIXC.SCR, etc.) AFTER your DIAL.SCR file, if any, or else
; AFTER your general script settings file (GENERAL.SCR).
;
output \13		; Send a carriage return
input 10 MODIFY?        ; Wait up to 10 seconds for Rolm prompt
pause 1                 ; Wait one second before replying
output CALL\32          ; Type CALL and an a space (ASCII 32)
;
; The host system login script will output the desired system to login to.
;
; To connect to a system, output CALL xxx\13, where xxx is the system name.
; and then wait for CALL COMPLETE message.
;
; ADD CU20.SCR, CUVM.SCR, SIM.SCR, CLIO.SCR, or CUNIXC.SCR HERE.
;
COMMENT - End Kermit ROLM Settings Script

==============================CUT HERE==============================

Suppose you usually connect to CUNIXC but sometimes you use the PACX 
(which will become the ROLM switch), sometimes you dial from home using a
modem, and other times you have access to a direct line to this computer.
How can you use scripts to connect to CUNIXC in various ways?  You simply
store all these script files on your disk and tell Kermit which file(s) you
would like to use.

* Note: In the following examples you could replace PACX.SCR with ROLM.SCR.

Example:

   A> KERMIT

   MS-KERMIT> TAKE GENERAL.SCR       (do general script)

   MS-KERMIT> TAKE DIAL.SCR          (only if dialing-up)

   MS-KERMIT> TAKE PACX.SCR          (you need this when
                                      dialing up through
                                      the PACX)

   MS-KERMIT> TAKE CUNIXC.SCR        (do cunixc script)

You may have access to many different computers at Columbia.  In the next
script message we will see how to write scripts to connect to these various 
machines.

------------------------------

Kermit Script Files: (PART 3 of 4)

This is the third part of the MS-DOS Kermit script tutorial.  So far we have
seen examples of scripts which will give us the general settings, scripts
which will connect our IBM PC to another computer if we are using an LDS-125
Gandalf PACX box, the ROLM switch, a Hayes or Hayes-compatible modem or a
direct line, and a script which allows us to login to CUNIXC with minimum
user interaction.

Now we will see examples of scripts for the various types of host computers
we have here at Columbia.  Just as we saw how to substitute our PACX.SCR
with our ROLM.SCR, we will see that we can also replace our CUNIXC.SCR with
any of the following scripts.

Below is an example of a script which will login to the DEC-20 Mainframe:

==============================CUT HERE==============================

; CU20.SCR
;
COMMENT Kermit script for connecting to CU DEC-20 system.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For use with the CUCCA DEC-20 mainframe systems.
; Add to the bottom of either PACX.SCR.
;
output cu20b\13             ; Tell the switch which system 
input 10 \64                ; Expect to see @ (DEC-20 prompt - ASCII 64 = @)
output login USERNAME\13    ; Type login username (replace with yours) & CR
set input echo off          ; Privacy, please
input word:                 ; Expect to see "password:" (abbrev.)
echo \13Type your password: ; Make our own prompt
output @con                 ; Type in password at the console
set input echo on	    ; Back to normal viewing
output \13                  ; Add a real carriage return
connect                     ; Connect to system
;
COMMENT - End of DEC-20 Script

==============================CUT HERE==============================

And here is a script which allows you to login to the IBM VM/CMS Mainframe
in linemode:

==============================CUT HERE==============================

; CUVM.SCR
;
COMMENT Kermit script for connecting to CU IBM system through the COMTEN.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For use with the CUCCA IBM VM/CMS mainframe systems.
; Add to the bottom of either PACX.SCR or ROLM.SCR.
;
set parity mark             ; IBM Mainframes use parity
set handshake xon           ; Set the hanshaking character
set flow none               ; Do not need flow control
set local on                ; Echo locally on the screen
output cuvm\13              ; Tell the switch which system
pause 1 	            ; Wait for COMTEN to crank itself up
output \13                  ; Send another CR for speed recognition
set input default 10        ; Set default timeout interval
input ACTERS:               ; Look for end of "valid switch chars" message
pause 1	                    ; Wait a sec to let COMTEN get ready for input
output vma\13               ; Tell it which system 
; output vmb\13             ; Can change system to vmb or vmc
pause 1			    ; Wait another sec for VM to wake up
input BREAK KEY             ; VM/SP5's new greeting...
output \b                   ; Send a BREAK, like it asks
input .\17                  ; Now wait for CMS's "." prompt
out logon USERNAME\13       ; Type username (replace with yours) & CR
pause 1                     ; Wait a sec
set input echo off          ; Privacy, please
input word:                 ; Expect to see password: (abbrev.)
echo \13Type your password: ; Make our own prompt.
out @con                    ; Console keystokes
set input echo on           ; Normal viewing again
input 30 .\17               ; Login messages type out, wait for prompt.
output \13                  ; Send another CR
input .\17                  ; Wait for CMS's "." prompt, followed by Ctrl-Q
output \13                  ; Send another CR
connect                     ; Connect to system
;
COMMENT - End of CUVM Line-Mode Script

==============================CUT HERE==============================

But you may sometimes use the 3270 simulator to access the IBM VM/CMS
mainframe in full-screen mode.  Below is an example of a script:

==============================CUT HERE==============================

; SIM.SCR
;
COMMENT Kermit script for connecting to CU IBM Mainframe.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For logging in to the Columbia IBM mainframes in fullscreen mode 
; through the 7171 protocol emulator.
; Add to the bottom of either PACX.SCR or ROLM.SCR.
;
set parity even             ; Set parity to match the remote system
output sima\13              ; Tell it which system 
; output simb\13            ; Can change this to simb too
input 5 NAL TYPE:\32        ; Wait to be asked what terminal you are using
output VT-100\13            ; Tell it you are a VT-100 & CR
input 20 COMMAND  ===>	    ; Look for this
output USERNAME\13          ; Send user ID (replace with your ID) & CR
connect                     ; Connect to system, type password there.
;
COMMENT - End of CUVM Full-Screen Script

==============================CUT HERE==============================

Or you may want to access CLIO, the library database.  Below is a script
written for this purpose.  Note that sometimes when you login to CLIO you
may enter the middle of a session.  If this happens, the Kermit script will
obviously not work.  You can run the script again and hope that you enter a
new session the second time.

==============================CUT HERE==============================

; CLIO.SCR
;
COMMENT Kermit script for connecting to CLIO.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For logging in to the Columbia CLIO system in fullscreen mode
; through the 7171 protocol emulator.
; Add to the bottom of either PACX.SCR or ROLM.SCR.
;
set parity even             ; Set parity to match the remote system
output clio\13              ; Tell it which system 
input 5 NAL TYPE:\32        ; Wait to be asked what terminal you are using
output VT-100\13            ; Tell it you are a VT-100 & CR
output \13                  ; Send a carriage return
pause 3                     ; Wait 3 seconds
output CLIO\9		    ; Login as CLIO, tab to password field
pause 1                     ; Wait 1 second
output CLIO\13              ; Password CLIO
connect
;
COMMENT - End of CLIO Full-Screen Script

==============================CUT HERE==============================

And still other users may have access to a VAX/VMS system.  Below is an
example of a script for logging in to such a computer.  There is currently
no access to any CUCCA VAX/VMS systems through the PACX.

==============================CUT HERE==============================

; VMS.SCR
;
COMMENT Kermit script for connecting to CU VAX/VMS system.
;
; MS-Kermit 2.30 Script File for the IBM PC, XT, AT, PS2, etc.
;
; For use with the CUCCA's VAX/VMS system using a direct line.
; VAX/VMS is not currently an option to choose on the PACX.
; Add to the bottom of GENERAL.SCR or (if dialing up) DIAL.SCR.
;
output \13                  ; Wake up the VAX
input username:\32          ; Look for login prompt
output USERNAME\13          ; Type username (replace with yours) & CR
set input echo off          ; Privacy, please
input Password:\32          ; expect to see "Password:"
echo \13Type your password: ; Make our own prompt.
output @con                 ; Type in password at your console
output \13                  ; Add a real carriage return
connect                     ; Connect to system
;
COMMENT - End of VAX/VMS Script

==============================CUT HERE==============================

Suppose you sometimes use each one of these different computers, and maybe
other systems as well.  How can you use these scripts to connect to these
various systems?  Just as we did before, we need to store all of these
script files on a disk and tell Kermit which ones we want to use.

* Note: In the following examples you would replace PACX.SCR with ROLM.SCR
        after the data cutover in the Fall 1988.

Example:

   A> KERMIT

   MS-KERMIT> TAKE GENERAL.SCR

   MS-KERMIT> TAKE DIAL.SCR		(only if you are dialing up)

   MS-KERMIT> TAKE PACX.SCR   <or> ROLM.SCR

   MS-KERMIT> TAKE CUNIXC.SCR <or> TAKE CU20.SCR <or> TAKE CUVM.SCR    <or>
              TAKE SIM.SCR    <or> TAKE CLIO.SCR <or> TAKE VMS.SCR (choose one)

All of this would work just fine in the example above, provided you didn't
take too long between TAKE commands.  You could always use the general
settings, use any method to make the connection, and communicate with any
computer.  There is however a way to define Kermit macros to put these
combinations together for you as we will see in the next message.

------------------------------

Kermit Script Files: (PART 4 of 4)

This is the fourth and final part of the MS-DOS Kermit script tutorial.  Now
that we can write and use scripts for any connection method and for any
computer, all we need to automate this process further is a method for
combining several scripts into one.  We could use our Kermit initialization
file (MSKERMIT.INI) to define macros to run several scripts at once.

Note that all Kermit diskettes are distributed with a file called
MSKERMIT.INI containing commands that are automatically each time you start
up the Kermit program.  If you look at this file you will see a definition
called "ibm" which combines all the parameters set individually at the top
of our CUVM script file (CUVM.SCR) into what is called a macro:

   define ibm set par mar,set han xon,set flo n,set loc on

By typing "DO IBM" at the KERMIT-MS> prompt, these Kermit commands will
executed.  Since scripts allow us to use commands that we would normally
type at the KERMIT-MS> prompt, we could also use this macro in a script.  We
could take the first four lines out of our CUVM script and add a single
line as long as it is defined in the file MSKERMIT.INI.

    do ibm                  ; Parameters defined in MSKERMIT.INI

In the same way we could use an editor to define another macro in our
MSKERMIT.INI file.  For example, we could take the last four lines of our
general script (GENERAL.SCR) and define a macro called "default" in our
MSKERMIT.INI file.  Let's assume we always want to begin a Kermit session
with these settings.
 
    define default set par non,set han non,set flo x,set loc of

Then we could replace the last four lines in our general script with a
single line:

    do default              ; Parameters defined in MSKERMIT.INI

   You can even use an editor to modify or create an MSKERMIT.INI file which
   will combine several scripts.  For example, you could combine your
   general script, your Hayes modem script, your PACX script (since you need
   to go through the PACX box currently at Columbia even when you are
   dialing up) and your CUNIXC script. 

Example:

 define dcunixc take general.scr, take dial.scr, take pacx.scr, take cunixc.scr

          A> KERMIT
  
          MS-KERMIT> DO DCUNIXC

   And, instead of having to store ALL the script files on your disk, which
   could be tedious if you are using floppy disks, you could define some of
   your scripts in MSKERMIT.INI as macros.  Below GENERAL.SCR, DIAL.SCR and
   PACX.SCR are defined in macros.  

Example:

GENERAL.SCR defined as a macro:
  def gnrl set speed 9600,set input echo on,set input timeout quit,do default

DIAL.SCR defined as a macro:
  def dial set sp 1200,o AT\13,i OK,pau,o ATDT 2808050\13,in 30 CONNECT,pau 2

PACX.SCR defined as a macro:
 def pacxmsg ech Turn on your PACX box\13,ech Type carriage return when ready..
 def pacx do pacxmsg, out @con, out \13, input 10 =>, pause 1  

 * Note:  The PACX script is defined with two macros because it is so long.
          Notice one macro can call another macro.  For example, the PACX
          macro then invokes the PACXMSG macro. 
 
   The macro in your MSKERMIT.INI file for combining your general script, 
   your dial script, your PACX script and your CUNIXC script would
   presumably look as follows:

Example:

      define dcunixc do gnrl, do dial, do pacx, take cunixc.scr

    But, if we are dialing up, we will not need to see the PACX message since
    there is no PACX box to turn on when ready.  What we need then is another
    macro which expects to dial the PACX -- the "dpaxc" macro which looks as
    follows:

Example:

      define dpacx do dial, out \13, input 10 =>, pause 1

    Then we could define dcunixc as we can see below to make it work properly:

Example:

      define cunixc do gnrl, do dpacx, take cunixc.scr

          A> KERMIT
  
          MS-KERMIT> DO DCUNIXC

Note that we will not need to include a "drolm" macro since Rolm doesn't
need to be 'turned on' before using.

There are several of these combinations which you could add to your
MSKERMIT.INI file.  Below is an example of an MSKERMIT.INI file which
attempts to combine all of CUCCA's host computer scripts with the various
methods of making such a connection.  You may use this file in place of your
own initialization file, or you may take parts of this file to add to your
own MSKERMIT.INI file.  To find out your macro options type "DO ?" at the
KERMIT-MS> prompt.

Notice that you can redefine your keyboard arrangement with the Kermit 
SET KEY command.

==============================CUT HERE==============================

; MS-Kermit 2.30 Initialization File for the IBM PC, XT, AT, PS2, etc.
;
; For use with CUCCA systems.
;
; GENERAL KERMIT SETTINGS
;  (You may want to change these to suit your computer or your tastes)
;
set port 1                 ; set the proper communication port
set speed 9600             ; set baud to match the remote system
set key \96 \27            ; put "escape key" in upper left corner of keyboard
set key \1280 \kbreak      ; put "break key" in the proper place on keypad
set warning off            ; change this to "on" to disallow overwriting files
set terminal vt102         ; emulate a DEC VT102 terminal
set terminal color 0 34 47 ; blue on white background
;
; PARAMETER SETTINGS FOR DIFFERENT HOST COMPUTERS AND FRONT ENDS:
;
; TYPE "DO DEC" (for DEC-20 systems), "DO VAX" (for VAX/VMS systems),
; "DO IBM" (for CUVM Line-Mode), "DO UNIX" (for UNIX systems)  
;
; THE KERMIT "SET KEY" COMMAND IN THE FOLLOWING EXAMPLES CHANGES THE
; BACKSPACE KEY SO THAT IT ERASES CHARACTERS.
;
define default set par non,set han non,set flo x,set loc of,set ke \270 \127
define dec do default
define vax do default
define unix do default
define ibm set par mar,set han xon,set flo n,set loc on,set ke \270 \8
;
; GENERAL SCRIPT SETTINGS
;
def gnrl set speed 9600, set input echo on, set input timeout quit, do default
;
; MACROS FOR HAYES MODEMS, PACX, 7171, OR DIRECT CONNECT.
; (TYPE "DO DIAL", "DO PACX", "DO DIRECT"...)
;
; CHANGE THE SPEED TO MATCH YOUR MODEM AND/OR REMOTE COMPUTER IF NEEDED 
; (300, 1200, 2400, 4800, 9600, etc...), AND CHANGE THE PHONE NUMBER
; IF NECESSARY, E.G. 2808050 to 8050 IF DIALING FROM INSIDE.
; (WARNING, PHONE NUMBERS WILL CHANGE WHEN THE ROLM CBX IS INSTALLED.)
;
def dial set sp 1200,o AT\13,i OK,pau,o ATDT 2808050\13,in 30 CONNECT,pau 2
def pacxmsg ech Turn on your PACX box\13,ech Type carriage return when ready..
def pacx do pacxmsg, out @con, out \13, input 10 =>, pause 1
def dpacx do dial, out \13, input 10 =>, pause 1
def rolm out \13, input 10 MODIFY?, pause 1
;
; MACROS FOR CONNECTING TO DIFFERENT CUCCA HOST COMPUTERS (DEC20, UNIX,
; VM/CMS LINEMODE AND FULLSCREEN) THROUGH A GANDALF LDS-125 PACX BOX.
; CUVMLM IS FOR LINEMODE CONNECTIONS, CUVMFS IS FOR FULLSCREEN CONNECTIONS.
; 
; TYPE "DO CU20" to automatically login to the DEC-20 thru the PACX, 
; "DO CUNIXC", etc.
;
define cu20b  do gnrl, do pacx, take cu20.scr
define cunixc do gnrl, do pacx, take cunixc.scr
define cuvmlm do gnrl, do pacx, take cuvm.scr
define cuvmfs do gnrl, do pacx, take sim.scr
define clio   do gnrl, do pacx, take clio.scr
;
; MACROS FOR LOGGING IN THROUGH THE ROLM SWITCH
;
define rcunixc do gnrl,  do rolm,  i 20 ALL COMPLETE,  take cunixc.scr
define rcuvmlm do gnrl,  do rolm,  i 20 ALL COMPLETE,  take cuvm.scr
define rcuvmfs do gnrl,  do rolm,  i 20 ALL COMPLETE,  take sim.scr
define rclio   do gnrl,  do rolm,  i 20 ALL COMPLETE,  take clio.scr
;
; MACROS FOR DIALING UP CUCCA HOST COMPUTERS THROUGH A HAYES MODEM.
;
; TYPE "DO DCU20" TO AUTOMATICALLY LOGIN TO THE DEC-20 WITH A MODEM,
; "DO DCUNIXC", ETC.  THIS ASSUMES YOU ARE GOING THRU PACX.  IF YOU
; ARE DIALING DIRECTLY INTO A COMPUTER, YOU WOULD FOLLOW THE EXAMPLES
; BELOW, REPLACING "DO DPACX" WITH "DO DIAL".
;
define dcu20b  do gnrl, do dpacx, take cu20.scr 
define dcunixc do gnrl, do dpacx, take cunixc.scr
define dcuvmlm do gnrl, do dpacx, take cuvm.scr
define dcuvmfs do gnrl, do dpacx, take sim.scr
; (Can't dial up CLIO!)
;
; MACROS FOR DIALING UP WITH A HAYES MODEM THROUGH THE ROLM SWITCH.
;
define drcunixc do gnrl,  do dial,  do rolm, i 20 COMPLETE,  take cunixc.scr
define drcuvmlm do gnrl,  do dial,  do rolm, i 20 COMPLETE,  take cuvm.scr
define drcuvmfs do gnrl,  do dial,  do rolm, i 20 COMPLETE,  take sima.scr
; (Can't dial CLIO)
;
; SAMPLE MACRO FOR DIRECT CABLE AND DIAL CONNECTIONS TO A HOST COMPUTER
; (VAX/VMS)
;
define lvms do gnrl,          take vms.scr
define dvms do gnrl, do dial, take vms.scr
;
echo End of MSKERMIT.INI.
;
; End of MSKERMIT.INI.


==============================CUT HERE==============================

You may want to design your own script files or modify some of the ones we
have shown to suit your own needs.  For more detailed information on any of
the material in the MS-DOS Kermit script tutorial, refer to the MS-DOS
Kermit User Guide available from the User Services Business Office in Room
321 SIA for $6.50.

------------------------------

   ======= END =======