$ ! BAKDSK.COM - Do a BACKUP of all disks on the system (that we know about)
$ ! 11-May-88 - Version to user 'helper' .TSK for device names
$ _on control_c then goto escape
$ _set nodata
$ _set noon
$ _ope/log/rep BAKDSK.LOG
$ _write 0 "This procedure will back up all of the disks onto tape."
$ _write 0 "It is suggested that you do a PURGE before proceeding."
$ _inquire/exit=byebye isgood "Do you wish to continue? (<Y>/N)"
$ _if f$left(f$edit(isgood,38),1) .eqs. "N" then _goto byebye
$ _write 0 ""
$ _run TOOLS:DSKTBL
$ _if f$left(dsktbl,1) .nes. "M" then _goto notape
$ tapdev=f$left(dsktbl,4)	! name of tape drive on system
$ dsktbl=f$mid(dsktbl,5,f$len(dsktbl))
$nxtdsk:
$ _if f$len(dsktbl) .eq. 0 then _goto alldun
$ dskdev=f$left(dsktbl,4)	! device name of current disk
$ dsknam=f$mid(dsktbl,5,9)	! full name (9 chars) for mounted pack
$ dsknam=f$edit(dsknam,38)	! trim trailing spaces
$ dskna6=f$left(dsknam,6)	! short name for backup set ID
$ dsktbl=f$mid(dsktbl,14,f$len(dsktbl))
$ _inquire/exit=byebye nxtdsk -
 "Do you wish to back up ''dskdev'''dsknam'? (<Y>/N)"
$ if f$left(f$edit(nxtdsk,38),1) .eqs. "N" then goto nxtdsk
$ _backup/account_data/in_label='dsknam'/initialize/listfile= -
 'dskna6'.LST/out_label='dskna6'/rewind/end=nodismount -
 'dskdev'[*,*]*.* 'tapdev''dskna6'.BCK
$ _copy 'dskna6'.LST 'tapdev'
$ _delete 'dskna6'.LST
$ _dismount 'tapdev'/unload
$ _write 0 "Please dismount this volume."
$ _if $severity .ge. 2 then goto isitok
$ _goto nxtdsk
$alldun:
$ _write 0 ""
$ _write 0 "The backup procedure is now complete."
$byebye:
$ _close/log
$ _print/queue=LP0: BAKDSK.LOG
$ _exit
$isitok:
$ _write 0 "Please inspect the console log for fatal errors and"
$ _write 0 "retry this volume if required."
$ _goto nxtdsk
$escape:
$ _set noon
$ _write 0 "?Aborted by Control-C"
$ _goto byebye
$notape:
$ _write 0 "?No tape units configured on system - cannot continue."
$ _goto byebye
                                                                                        