15600	!-------------------------------------------------------------------- &
	!								      &
	!	        FNDCNV  -  Date Conversion			      &
	!								      &
	!-------------------------------------------------------------------- &
	!								      &
	!	             FN.DATE.CNV$ (INP.DATE$)			      &
	!								      &
	!	Converts a valid date from DD-MMM-YY format to YYMMDD	      &
	! 	format.							      &
	!								      &
        !								      &
	!	INP.DATE$		Input date			      &
	!	MMM$			Month abbreviation		      &
	!	MM%			Integer month (1-12)		      &
	!	MM$			Character month ("01"-"12")	      &
	!	FN.DATE.CNV$		Output of function		      &
	!								      &
	!								      &
	!  assumption:  the input date is a valid DD-MMM-YY date	      &
	!								      &
	!-------------------------------------------------------------------- &
									      &

15610	  DEF FN.DATE.CNV$  (INP.DATE$)					      &
	\ INP.DATE$ = EDIT$ (INP.DATE$, (8%+32%+128%)) 			      &
	\ INP.DATE$ = "0" + INP.DATE$       IF LEN(INP.DATE$) < 9%	      &
									      &
	\ MMM$ = "," + SEG$ (INP.DATE$, 4%, 6%) + ","			      &
	\ MM% =								      &
	   POS(",JAN,FEB,MAR,APR,MAY,JUN,JUL,AUG,SEP,OCT,NOV,DEC,",MMM$,1%)   &
	\ MM% = (MM% + 3%) / 4%						      &
	\ MM$ = NUM1$ (MM%)						      &
	\ MM$ = "0" + MM$ IF MM% < 10%					      &
	\ FN.DATE.CNV$ = SEG$ (INP.DATE$, 8%, 9%)  + MM$		      &
                       + SEG$ (INP.DATE$, 1%, 2%)		   	      &
	\ FNEND								      &
									      &
	! Convert DD-MMM-YY to YYMMDD. Isolate month string and convert to a  &
	! number between 1-12. Then build YYMMDD string.		      &