/*
	u91-8m.pld --
	This is a re-implementation of the PAL at position U91 of the 701-2313 control board
	that supports 8MB of RAM.
*/
Name     U91-8M ;
PartNo   00 ;
Date     2/1/2011 ;
Revision 01 ;
Designer Engineer ;
Company  Name ;
Assembly None ;
Location  ;
Device   p22v10; /* Omit UES data */

/* Inputs */

pin	1	=	dgd;	/* */
pin	2	=	a23;	/* */
pin	3	=	a22;	/* */
pin	4	=	a21;	/* */
pin	5	=	a20;	/* */
pin	6	=	a19;	/* */
pin	7	=	a18;	/* */
pin	8	=	a17;	/* */
pin	9	=	ras;	/* */
pin	10	=	emul;	/* */
pin	11	=	rw;	/* */
pin	13	=	tst;
pin	15	=	per;	/* */
pin	18	=	rrs;	/* */
pin	19	=	asd;	/* */
pin	20	=	bde;	/* */

/* Outputs */

pin	14	=	pwr;	/* */
pin	16	=	dtk;	/* */
pin	17	=	bfe;	/* */
pin	21	=	rom;	/* */
pin	22	=	rs1;	/* */
pin	23	=	rs0;	/* */

field	a	=	[a23,a22,a21,a20,a19,a18,a17];

/* Logic equations */

!pwr		=	a:[060000..07FFFF] & bde & !asd & ras & !rw
		;

!bfe		=	a:[900000..9FFFFF] & bde & !dgd & ras
		#	a:[F00000..FFFFFF] & bde & ras
		;

!rom		=	a:[000000..01FFFF] & bde & ras & rw
		;

dtk		=	a:[000000..01FFFF] & bde & ras & rw
		#	a:[060000..07FFFF] & bde & ras
		#	a:[080000..0FFFFF] & bde & rrs & ras
		#	a:[100000..1FFFFF] & bde & rrs & per & asd
		#	a:[200000..8FFFFF] & bde & rrs & per & asd
		#	a:[900000..9FFFFF] & bde & rrs & per & asd & dgd
		#	a:[E00000..EFFFFF] & bde & rrs & per & asd
		;

!rs0		=	a:[080000..0FFFFF] & bde & ras & emul
		#	a:[900000..9FFFFF] & bde & ras & emul & dgd
		#	a:[E00000..E7FFFF] & bde & ras & emul
		#	!rrs
		;

!rs1		=	a:[100000..8FFFFF] & bde & ras & emul
		#	!rrs
		;

pwr.oe		=	tst;
rom.oe		=	tst;
bfe.oe		=	tst;
dtk.oe		=	tst;
rs0.oe		=	tst;
rs1.oe		=	tst;

/* End */