ASMB,R,L,C
HED COMPILER LIBRARY ID FINDER ROUTINE
NAM C.RPL,7 92070-16250 REV. 1940 781229 $CLIB
*
*
***************************************************************
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1977. ALL RIGHTS *
* RESERVED. NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, RE- *
* REPRODUCED, OR TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITH- *
* OUT THE PRIOR WRITTEN CONSENT OF HEWLETT-PACKARD COMPANY. *
***************************************************************
*
*
*
* SOURCE PART NUMBER : 9206 -18
*
*
* THIS ROUTINE WILL MAKE SURE THAT THE ROUTINE YOU ARE TRYING
* TO SCHEDULE IS AVAILABLE TO RUN.
*
*
* CALLING SEQUENCE:
*
* LDB
* JSB C.RP
*
*
*
* ON NORMAL RETURN A = 0
* (FOR FUNC>0)
* B = ADDRESS OF NAME
*
* WHERE = 1 do not modify the name, just find
* = 0 delete (will nop in RTE-L)
* registers meaningless
* = x use x as the last two digits of newname
*
*
*
* ENTRY POINT:
*
ENT C.RP
*
* EXTERNALS:
*
EXT IDRPL SYSTEM RP ROUTINE
EXT OPEN
EXT CLOSE
*
*
*
*
*
.0 OCT 0
.1 OCT 1
.19 DEC 19
DCB BSS 144
IERR BSS 1
IER BSS 1
*
C.RP NOP
STB .NM SAVE ADDRESS OF NAME
SZA,RSS
JMP EXC+1 JUMP OUT - DELETE NOT REQD IN LC
JSB OPEN TRY TO FIND FILE BY THAT NAME
DEF *+7
DEF DCB
DEF IERR
.NM BSS 1
DEF .1
DEF .0
DEF .0 ON ALL MOUNTED DISCS
LDA IERR
SSA
JMP C.RP,I IF NO ERROR,
JSB IDRPL RP THE FILE
DEF *+4
DEF DCB
DEF IER
DEF .NM,I
JSB CLOSE CLOSE THE FILE
DEF *+3
DEF DCB
DEF IERR
LDA IERR
SSA
JMP C.RP,I ERROR ON CLOSE -- JUMP OUT
LDA IER
CPA .19 JUMP OUT IF RP ERROR IS 19 (NO IN SYSTEM)
JMP C.RP,I
CLA CLR DUP FLAG (DEL DONE BY OP SYS)
EXC LDB .NM
ISZ C.RP
JMP C.RP,I
SPC 3
END