ASMB,L,C,R
      HED DBDEL SUBROUTINE FOR REMOTE ONLY ACCESS 
      NAM DBDEL,7 92069-16242 REV.1912 790130 
* 
* 
******************************************************************* 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS RESERVED.
* NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, REPRODUCED, OR
* TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR WRITTEN
* CONSENT OF HEWLETT-PACKARD COMPANY. 
******************************************************************* 
* 
* 
*     SOURCE:    92069-18242
*     RELOC:     92069-16242
* 
*     PRGMR:     CEJ
* 
* 
******************************************************************* 
* 
* 
* 
*  This version of DBDEL is for remote only data base access.  It assumes 
*  that the data base is remote and merely provides an interface between
*  the user and RBDEL which handles the remote Delete.
* 
*  The calling sequence for DBDEL is: 
* 
*          JSB DBDEL
*           DEF *+5      return point 
*           DEF BASE     the data base parameter used in a successful 
*                          remote DBOPN for the data base from which the
*                          entry is to be removed.  The data base must have 
*                          been opened in mode 1 or 3, and if mode 1 must 
*                          have been previously locked to the user. 
*           DEF SET      the name or number of the manual master or detail
*                          data set from which the current entry is to be 
*                          deleted. 
*           DEF MODE     DBDEL mode = 1 
*           DEF STAT     a 10 word status array of which only the first 
*                          word is used by this subroutine to return to 
*                          the user a status code, zero if successful.
* 
      SKP 
A     EQU 0 
B     EQU 1 
* 
      ENT DBDEL 
      EXT .ENTR,DBIDS,RBDEL 
* 
BASE  NOP 
SET   NOP 
MODE  NOP 
STAT  NOP 
* 
*  Get true parameter and return point addresses. 
* 
DBDEL NOP 
      JSB .ENTR 
       DEF BASE 
* 
*  Make sure all the parameters are there.
* 
      LDA STAT
      SZA,RSS 
      JMP EXIT      Missing parameter.
* 
*  Ask DBIDS to check the data base specified in BASE to see if it is 
*  valid, and if so to set up its Run Table as the current Run Table. 
* 
      CCA           A = -1 signifies not DBOPN calling. 
      JSB DBIDS 
       DEF *+2
       DEF BASE,I 
* 
      JMP E103      Error return - illegal BASE param.
      NOP           (Local data base return - ignore.)
* 
*  Ask RBDEL to handle this request.
* 
      JSB RBDEL 
       DEF *+5
       DEF BASE,I 
       DEF SET,I
       DEF MODE,I 
       DEF STAT,I 
* 
*  Reset STAT to zero for parameter check on next entry.
* 
EXIT  CLA 
      STA STAT
* 
*  Return to user.
* 
      JMP DBDEL,I 
* 
*  Error return points. 
* 
E103  LDA D103      Illegal BASE parameter. 
      STA STAT,I
      JMP EXIT
* 
* 
D103  DEC 103 
      END 
      END$
                              