ASMB,L,C,R
      HED DBGET SUBROUTINE FOR REMOTE ONLY ACCESS 
      NAM DBGET,7 92069-16239 REV.1912 790130 
* 
* 
******************************************************************* 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS RESERVED.
* NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, REPRODUCED, OR
* TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR WRITTEN
* CONSENT OF HEWLETT-PACKARD COMPANY. 
******************************************************************* 
* 
* 
*     SOURCE:    92069-18239
*     RELOC:     92069-16239
* 
*     PRGMR:     CEJ
* 
* 
******************************************************************* 
* 
* 
* 
*  This version of DBGET is for remote only data base access.  It assumes 
*  that the data base is remote and merely provides an interface between
*  the user and RBGET which handles the remote Get. 
* 
*  The calling sequence for DBGET is: 
* 
*           JSB DBGET 
*            DEF *+8         return point 
*            DEF IBASE       the data base parameter used on a successful 
*                              remote DBOPN call for the data base from 
*                              which data is to be retrieved. 
*            DEF ISET        the name or number of the detail or manual 
*                              master data set from which data is to be 
*                              retrieved. 
*            DEF IMODE       DBGET mode, a one word integer.
*            DEF ISTAT       a ten word array in which the following is 
*                              returned to the user:
*                              word                contents 
*                              ----                -------- 
*                                1       error code (zero if successful)
*                                  If successful: 
*                                2       word length of data returned.
*                               3-4      record # of entry read 
*                               5-6      zero 
*                               7-8      record # of predecessor of entry 
*                                          read along current chain 
*                               9-10     record # of successor of entry 
*                                          read along current chain 
*            DEF LIST        a list of item names or numbers whose values 
*                              are to be returned to the user from the
*                              entry read 
*            DEF IBUF        the buffer into which the item values of the 
*                              items specified in LIST are to be put con- 
*                              catenated together in the order of the 
*                              items in LIST
*            DEF IARG        a doubleword record number for mode 4
*                                           or
*                            the key item value for mode 7
* 
      SKP 
A     EQU 0 
B     EQU 1 
* 
      ENT DBGET 
      EXT .ENTR,DBIDS,RBGET 
* 
BASE  NOP 
SET   NOP 
MODE  NOP 
STAT  NOP 
LIST  NOP 
BUF   NOP 
ARG   NOP 
* 
*  Get true parameter and return point addresses
* 
DBGET NOP 
      JSB .ENTR 
       DEF BASE 
* 
*  Make sure all the parameters are there.
* 
      LDA ARG 
      SZA,RSS 
      JMP E162      Missing parameter.
* 
*  Ask DBIDS to check the data base specified in BASE to see if it is 
*  valid, and if so to set up its Run Table as the current Run Table. 
* 
      CCA           A = -1 signifies not DBOPN calling. 
      JSB DBIDS 
       DEF *+2
       DEF BASE,I 
* 
      JMP E103      Error return - illegal BASE param.
      NOP           (Local data base return - ignore.)
* 
*  Ask RBGET to handle this request.
* 
      JSB RBGET 
       DEF *+8
       DEF BASE,I 
       DEF SET,I
       DEF MODE,I 
       DEF STAT,I 
       DEF LIST,I 
       DEF BUF,I
       DEF ARG,I
* 
*  Reset ARG to zero for parameter check on next entry. 
* 
EXIT  CLA 
      STA ARG 
* 
*  Return to caller.
* 
      JMP DBGET,I 
* 
*  Error return points. 
* 
E103  LDA D103      Illegal base parameter. 
      RSS 
E162  LDA D162      Missing parameter.
      STA STAT,I
      JMP EXIT
* 
* 
D103  DEC 103 
D162  DEC 162 
      END 
      END$
        