ASMB,L,C,R
      HED DBINF SUBROUTINE FOR REMOTE ONLY ACCESS 
      NAM DBINF,7 92069-16237 REV.1912 790130 
* 
* 
******************************************************************* 
* (C) COPYRIGHT HEWLETT-PACKARD COMPANY 1979. ALL RIGHTS RESERVED.
* NO PART OF THIS PROGRAM MAY BE PHOTOCOPIED, REPRODUCED, OR
* TRANSLATED TO ANOTHER PROGRAM LANGUAGE WITHOUT THE PRIOR WRITTEN
* CONSENT OF HEWLETT-PACKARD COMPANY. 
******************************************************************* 
* 
* 
*     SOURCE:    92069-18237
*     RELOC:     92069-16237
* 
*     PRGMR:     CEJ
* 
* 
******************************************************************* 
* 
* 
* 
*  This version of DBINF is for remote only data base access.  It assumes 
*  that the data base is remote and merely provides an interface between
*  the user and RBINF which handles the remote Info call. 
* 
*  The calling sequence for DBINF is: 
* 
*       JSB DBINF 
*        DEF *+6        return point
*        DEF IBASE      data base about which information is to be returned.
*                         This must be the same parameter as used in a
*                         successful remote DBOPN call for the data base. 
*        DEF ID         a data set name or number   or
*                       a data item name or number
*                         (When the mode calls for a specific set or item.) 
*        DEF MODE       DBINF mode, a one word integer. 
*        DEF STAT       status return array of the form:
*                         1st word always the status word, zero on a suc- 
*                           cessful return
*                         2nd word contains the word length of the informa- 
*                           tion in the BUF parameter when 1st word is
*                           zero. 
*        DEF BUF        buffer to contain returned information (supplied
*                         information on a 402 call). 
* 
      SKP 
      ENT DBINF 
      EXT .ENTR,DBIDS,RBINF 
* 
A     EQU 0 
B     EQU 1 
* 
BASE  NOP 
ID    NOP 
MODE  NOP 
STAT  NOP 
BUF   NOP 
* 
*  Get true parameter and return point addresses. 
* 
DBINF NOP 
      JSB .ENTR 
       DEF BASE 
* 
*  Make sure all the parameters are there.
* 
      LDA BUF 
      SZA,RSS 
      JMP E162      Missing parameter.
* 
*  Ask DBIDS to check the data base specified in BASE to see if it is 
*  valid, and if so to set up its Run Table as the current Run Table. 
* 
      CCA           A = -1 signifies not DBOPN calling. 
      JSB DBIDS 
       DEF *+2
       DEF BASE,I 
* 
      JMP E103      Error return - illegal BASE param.
      NOP           (Local data base return - ignore.)
* 
*  Ask RBINF to handle this request.
* 
      JSB RBINF 
       DEF *+6
       DEF BASE,I 
       DEF ID,I 
       DEF MODE,I 
       DEF STAT,I 
       DEF BUF,I
* 
*  Reset BUF to zero for parameter check on next entry. 
* 
EXIT  CLA 
      STA BUF 
* 
*  Return to caller.
* 
      JMP DBINF,I 
* 
*  Error return points. 
* 
E103  LDA D103      Illegal BASE parameter. 
      RSS 
E162  LDA D162      Missing parameter.
      STA STAT,I
      JMP EXIT
* 
* 
D103  DEC 103 
D162  DEC 162 
      END 
      END$
                                            