/FIXED POINT TRACE #1
/STARTING ADDRESS 6400. CAN BE PUT ON ANY TWO
/CONSECUTIVE PAGES BY CHANGING THE ONE ORIGIN
/SETTING INSTRUCTION WHICH FOLLOWS
/
/
/
          *6400
/
/
/
START,    LAS HLT
          DCA        PROCNT
          DCA        LINK
          DCA        ACCUM
BACK,     JMS I      TYPCPP
          TAD I      PROCNT
          DCA        INST
          TAD        PROCNT
          JMS I      OUT4P
          TAD        INST
          JMS I      OUT4P
          TAD        INST
          AND        NOPE
          DCA        OPCODE
          TAD        SKIP
          DCA        B7
          TAD        INST
          AND        PAGENO
          SNA CLA
          JMP I      B2PP
          TAD        MASK5
          AND        PROCNT
          DCA        ADDR
          TAD        MASK7
          AND        INST
          TAD        ADDR
          DCA        ADDR
          TAD        INDRCT
          AND I      PROCNT
          SNA CLA
          JMP        .+3
          TAD I      ADDR
          DCA        ADDR
          TAD        OPCODE
          TAD        P4000
          SNA CLA
          JMP        B6
          SZL
          JMP        B5
B4,       TAD        OPCODE
          TAD        BASIC
          DCA        I2
B1,       TAD        LINK
          RAR
          TAD        ACCUM
I2,        0
          SKP
          ISZ        PROCNT
          ISZ        PROCNT
          DCA        ACCUM
          RAL
          DCA        LINK
          TAD        LINK
          JMS I      OUT1P
          TAD        ACCUM
          JMS I      OUT4P
B7,       0
          JMP        BACK
          TAD        ADDR
          JMS I      OUT4P
          TAD I      ADDR
          JMS I      OUT4P
          JMP        BACK
B5,       TAD        OPCODE
          TAD        P2000
          SNA CLA
          JMP        B8
          SNL
          JMP        B9
          TAD        ADDR
          DCA        PROCNT
          TAD I      JMPP
          JMS I      OUTPP
          TAD        ADDR
          JMS I      OUT4P
          JMP        BACK
B8,       TAD I      IOTP
          JMS I      OUTPP
          TAD        INST
          DCA        I2
          TAD        NOPE
          DCA        B7
          JMP        B1
B9,       TAD I  OPRP
          JMS I      OUTPP
          JMP        .-7
B6,       TAD I      JMSP
          JMS I      OUTPP
          TAD        ADDR
          JMS I      OUT4P
          LAS
          SNA CLA    / CAN BE CHANGED TO SZA CLA
          JMP        .+4
          TAD        NOPE
          DCA        B7
          JMP        B4
          ISZ        PROCNT
          TAD        PROCNT
          DCA I      ADDR
          TAD        ADDR
          IAC
          DCA        PROCNT
          JMP        BACK
PROCNT,0
LINK,0
ACCUM,0
INST,0
OPCODE,0
SKIP,     SKP
PAGENO,   0200
MASK5,    7600
ADDR,0
MASK7,    0177
INDRCT,   0400
P4000,    4000
BASIC,    AND I      ADDR
P2000,    2000
NOPE,     NOP
          NOP
JMSP,     JMSTBL-1
OPRP,     OPRTBL-1
IOTP,     IOTTBL-1
OUTPP,    OUT
JMPP,     JMPTBL-1
OUT1P,    OUT1B
B2PP,     B2
OUT4P,    OUT4
TYPCPP,   TYPCR
PRINT1,   0
          NOP
          TLS
          TSF
          JMP        .-1
          JMP I      PRINT1
PRINT0,   0
          JMS        PRINT1
          CLA
          JMP I      PRINT0
OUT,      0
          DCA        INDEXC
          TAD I      INDEXC
          SNA
          JMP        OUT+10
          JMS        PRINT0
          ISZ        INDEXC
          JMP        OUT+2
          CLA CLL
          TAD        INST1A
          DCA        OUT+4
          TAD        SPCTBL-1
          JMP        OUT+1
          TAD        INST2A
          DCA        OUT+4
          CLL
          JMP I      OUT
INST1A,   JMP        OUT+15
INST2A,    JMP        OUT+10
INDEXC,    0
OUT1B,    0
          TAD        CONST5
          JMS        PRINT0
          TAD        SPCTBL-1
          JMS       OUT
          JMP I      OUT1B
CONST5,   0260
OUT4,     0
          DCA        PTEM
          TAD        CONST4
          DCA        DCN
          TAD        PTEM
          CLL RAL
PNU2,     RAL
          RTL
          DCA        PTEM
          TAD        PTEM
          AND        PCON
          TAD        CONST5
          JMS        PRINT0
          TAD        PTEM
          ISZ        DCN
          JMP        PNU2
          CLA
          TAD        SPCTBL-1
          JMS        OUT
          JMP I      OUT4
DCN,      0
PTEM,     0
CONST4,   7774
PCON,     0007
TYPCR,    0
          TAD        CARRTN
          JMS        PRINT0
          TAD        LINFED
          JMS        PRINT0
           CLL
          JMP I      TYPCR
CARRTN,   0215
LINFED,   0212
          .+1
JMPTBL,   0312
          0315
          0320
          0000
          .+1
IOTTBL,   0311
          0317
          0324
          0000
          .+1
OPRTBL,   0317
          0320
          0322
          0000
          .+1
JMSTBL,   0312
          0315
          0323
          0000
          .+1
SPCTBL,   0240
          0240
          0000
B2,       TAD I      INSTP
          AND        MSK416
          SZA CLA
          JMP I      B22P
          TAD I      INSTP
          AND        MSK10
          SNA CLA
          JMP I      B22P
          TAD I      INSTP
          DCA I      I2P
          TAD I      INSTP
          AND        MSK17P
          DCA        TRCTMP
          TAD I      INSTP
          AND        MSK400
          SZA CLA
          JMP        .+4
          TAD        TRCTMP
          DCA I      ADDRP
          JMP I      B22P
          TAD I      TRCTMP
          IAC
          JMP        .-4
MSK416,4160
MSK10,0010
MSK17P,0017
MSK400,0400
TRCTMP,0
B1P,      B1
ADDRP,    ADDR
I2P,      I2
B22P,     BACK+22
INSTP,    INST
NOP
$