.TITLE BIN-SRC     /BINARY TO SOURCE CONV.
/WRITTEN BY V. KEZYS 1973.
/FOR PDP-15.
/ PROGRAM TO READ BINARY CODE FROM CORE
/AND PRINT (TTY) ADDRESS,OCTAL CODE AND
/NMEMONIC IF ANY. CAL IS IGNORED.
 .ABS
 .LOC 2000
TLS=700406
TSF=700401
BEGIN JMS CRLF
 LAS       /LOAD IN STARTING ADDRESS              
 DAC AD
 HLT
 LAS        /LOAD IN # WORDS
 TCA        /TO BE PROCESSED
 DAC NWDS
LOOP LAC AD
 JMS PRA
 JMS PRS
 LAC* AD
 JMS PRI
 LAC* AD
 AND (760000
 SAD (760000
 JMP NLAW
 AND (700000
 SAD (700000
 JMP OP
 LAC* AD
 AND (740000
 RTL
 RTL
 RAL
 CLL
 SNA
 JMP END
 ADD (LAC MDSP
 DAC NXT
 JMS PRS
NXT XX
 JMS PRN
 LAC* AD
 AND (020000
 SNA
 JMP .+3
 LAC (052
 JMS PR
 LAC (040
 JMS PR
 LAC* AD
 AND (17777
 JMS PRA
 JMP END
NLAW JMS PRS
 LAC SLAW
 JMS PRN
 LAC (040
 JMS PR
 LAC* AD
 AND (17777
 JMS PRA
 JMP END
OP LAC NWOP
 DAC TST
 LAC (OPG
 DAC SADD    /TABLE SEARCH ADDRESS
TSLP LAC* AD
 SAD* SADD
 SKP
 JMP NXTOP
 ISZ SADD
 JMS PRS
 LAC* SADD
 JMS PRN
 JMP END
NXTOP ISZ SADD
 ISZ SADD
 ISZ TST
 JMP TSLP+1
END JMS CRLF
 ISZ AD
 ISZ NWDS
 JMP LOOP
 HLT
 JMP BEGIN
PR 0
 TLS
 TSF
 JMP .-1
 JMP* PR
CRLF 0
 LAC (015
 JMS PR
 LAC (012
 JMS PR
 JMP* CRLF
PRS 0
 LAC (040
 .REPT 4
 JMS PR
 JMP* PRS
PRN 0
 DAC WD
 CLL
 AND (770000
 RTL
 RTL
 RTL
 RAL
 XOR (300
 JMS PR
 CLL
 LAC WD
 AND (7700
 RTR
 RTR
 RTR
 XOR (300
 JMS PR
 CLL
 LAC WD
 AND (77
 XOR (300
 JMS PR
 JMP* PRN
PRI 0
 DAC WD
 LAC (-6
 DAC NCHAR
 JMS PRNT
 JMP* PRI
PRA 0
 RTL
 RAL
 DAC WD
 LAC (-5
 DAC NCHAR
 JMS PRNT
 JMP* PRA
PRNT 0
PRL LAC WD
 RTL
 RAL
 DAC WD
 RAL
 AND MSK
 XOR (260
 JMS PR
 ISZ NCHAR
 JMP PRL
 JMP* PRNT
AD
NWDS
SLAW .SIXBT 'LAW'
NWOP -51
TST
SADD
WD
NCHAR
MSK 7
TEMP
MDSP .SIXBT 'CAL'
 .SIXBT 'DAC'
 .SIXBT 'JMS'
 .SIXBT 'DZM'
 .SIXBT 'LAC'
 .SIXBT 'XOR'
 .SIXBT 'ADD'
 .SIXBT 'TAD'
 .SIXBT 'XCT'
 .SIXBT 'ISZ'
 .SIXBT 'AND'
 .SIXBT 'SAD'
 .SIXBT 'JMP'
OPG CLA
 .SIXBT 'CLA'
 RTL
 .SIXBT 'RTL'
 RTR
 .SIXBT 'RTR'
 SMA
 .SIXBT 'SMA'
 SZA
 .SIXBT 'SZA'
 SNL
 .SIXBT 'SNL'
 SKP
 .SIXBT 'SKP'
 SPA
 .SIXBT 'SPA'
 SNA
 .SIXBT 'SNA'
 SZL
 .SIXBT 'SZL'
 TCA
 .SIXBT 'TCA'
 CMA
 .SIXBT 'CMA'
 RAL
 .SIXBT 'RAL'
 RAR
 .SIXBT 'RAR'
 700401
 .SIXBT 'TSF'
 700406
 .SIXBT 'TLS'
 700301
 .SIXBT 'KSF'
 700312
 .SIXBT 'KRB'
 700002
 .SIXBT 'IOF'
 700042
 .SIXBT 'ION'
 700314
 .SIXBT 'RFL'
 700101
 .SIXBT 'RSF'
 700144
 .SIXBT 'RSB'
 700112
 .SIXBT 'RRB'
 700201
 .SIXBT 'PSF'
 700202
 .SIXBT 'PCF'
 700204
 .SIXBT 'PSA'
 700244
 .SIXBT 'PSB'
 703302
 .SIXBT 'CAF'
 707764
 .SIXBT 'EBA'
 707762
 .SIXBT 'DBA'
 CLL
 .SIXBT 'CLL'
 HLT
 .SIXBT 'HLT'
 CML
 .SIXBT 'CML'
 IAC 
 .SIXBT 'IAC'
 CLC
 .SIXBT 'CLC'
 GLK
 .SIXBT 'GLK'
 RCL
 .SIXBT 'RCL'
 RCR
 .SIXBT 'RCR'
 STL
 .SIXBT 'STL'
 SWHA
 .SIXBT 'SWH'
 LAS
 .SIXBT LAS
 OAS
 .SIXBT 'OAS'
 NOP
 .SIXBT 'NOP'
 .END BEGIN
`}