/ 
/ 
/                   FIRST PRINTING, FEBRUARY 1974
/ 
/ THE INFORMATION IN THIS DOCUMENT IS SUBJECT TO 
/ CHANGE WITHOUT NOTICE AND SHOULD NOT BE CONSTRUED
/ AS A COMMITMENT BY DIGITAL EQUIPMENT CORPORATION.
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPON-
/ SIBILITY FOR ANY ERRORS THAT MAY APPEAR IN THIS
/ DOCUMENT.
/ 
/ THE SOFTWARE DESCRIBED IN THIS DOCUMENT IS FUR-
/ NISHED TO THE PURCHASER UNDER A LICENSE FOR USE ON
/ A SINGLE COMPUTER SYSTEM AND CAN BE COPIED (WITH
/ INCLUSION OF DIGITAL'S COPYRIGHT NOTICE) ONLY FOR 
/ USE IN SUCH SYSTEM, EXCEPT AS MAY OTHERWISE BE PRO-
/ VIDED IN WRITING BY DIGITAL.
/ 
/ DIGITAL EQUIPMENT CORPORATION ASSUMES NO RESPONSIBILITY
/ FOR THE USE OR RELIABILITY OF ITS SOFTWARE ON EQUIP-
/ MENT THAT IS NOT SUPPLIED BY DIGITAL.
/ 
/ COPYRIGHT (C) 1974, BY DIGITAL EQUIPMENT CORPORATION
/ 
/ 
        .EJECT
/ EDIT #3
/
/ COPYRIGHT 1971, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/
/ LOG                 16 APR 71                H. KREJCI
/
/ SUBROUTINE TO LOG TIME & MESSAGE ON LUN 3
/
/ CALLING SEQUENCE:
/	JMS*	LOG
/	.ASCII "TEXT OF MESAGE"<15>
/
	.GLOBL	LOG
/
TBZ=74
HH=165
MM=164
SS=163
X13=13
.INH=705522
.ENB=705521
/
LOG	0
	.INH		/FETCH TIME, CONVERT TO IMAGE
	LAC*	(HH)	/ASCII, AND STORE IN OUTPUT BUFFER
	DAC	HT
	LAC*	(MM)
	DAC	MT
	LAC*	(SS)
	.ENB
	DAC	ST
	LAC	(HT-1)
	DAC*	(X13)
	LAC	HT
	JMS	CTP
	LAC	MT
	JMS	CTP
	LAC	ST
	JMS	CTP
/
	LAC	(TEXT-1)/FETCH TEXT, CONVERT TO IMAGE
	DAC*	(X13)	/ASCII, AND STORE IN OUTPUT BUFFER.
	DZM	TXC
	LAW	-TBZ
	DAC	OVC
/
FETX	LAC*	LOG
	ISZ	LOG
	LMQ
	LAC*	LOG
	ISZ	LOG
	PAL
	LLS	7
	JMS	STCX
	LLS	7
	JMS	STCX
	LLS	4
	PAX
	PLA
	LMQ
	PXA
	LLS	3
	JMS	STCX
	LLS	7
	JMS	STCX
	LLS	7
	JMS	STCX
	JMP	FETX
/
TXCD	LAW	012	/TEXT CONVERTED -- STORE A LF AND A NUL (IN CASE
	JMS	STCX	/TEXT LENGTH WAS EVEN)
	LAW	177
	JMS	STCX
/
	LAC	TXC	/SETUP HEADER
	RCR
	SWHA
	TAD	(007003)
	DAC	TIME
/
	CAL	WRITE	/WRITE TO LUN 3
	CAL	WAIF
/
	JMP*	LOG	/EXIT LOG SUBROUTINE
/
CTP	0		/SUBROUTINE TO CONVERT & STORE TIME PARAMETER
	CLL
	IDIV
	12
	PAL
	LACQ
	XOR	(60)
	DAC*	X13
	PLA
	XOR	(60)
	DAC*	X13
	LAC*	X13
	JMP*	CTP
/
STCX	0		/SUBROUTINE TO STORE TEXT CHAR & CHECK FOR CAR RTN
	ISZ	OVC
	SKP
	CAL	(10)
	AND	(177)
	DAC*	X13
	ISZ	TXC
	SAD	(015)
	JMP	TXCD
	JMP*	STCX
/
TXC	0		/TEXT CHAR COUNT
OVC	0		/OVER FLOW CHECK
/
WRITE	2700
	EV
	3
	3
	TIME
/
WAIF	20
	EV
/
EV	0
/
TIME	XX
	000000
HT	XX
	XX
	072
MT	XX
	XX
	072
ST	XX
	XX
	040
	055
	055
	040
TEXT	.BLOCK TBZ	/TEXT BUFFER
/
	.END