.GLOBL	BEGIN,DECODE,DISPO,KBFIX,LIST
	.GLOBL	LPON,SAV,SUBTAG,TABLEB,TABLEN
	.GLOBL	TVALUE,SAVE,START,COPY,FILER
/
/
/
	.LOC 7000
	.IODEV 3,4,5,6
IDCF=700704
IDLA=700606
IDRS=700504
DBR=703344
IDRC=700712
DBK=703304
IOF=700002
ISA=705504
CAF=703302
TLS=700406
TSF=700401
TCF=700402
IDSI=700601
IDSP=700701
IDVE=700501
IDHE=701001
IDSC=701012
IDRA=700512
/
/
/
TSTART	JMP	START
/
LENGTH=200
/
/
/
/    THIS IS THE DISPLAY SUBROUTINES FOLLOWED BY THE 
/     USERS FILES
TABLEB	.DSA	0
	.REPT 10
	.DSA	0
	.BLOCK 600
TVALUE	.DSA	0
	.REPT 10
	.DSA	0
	.BLOCK 300
/
/
/  COMPONENTS
/
/
RV	100100
	220000
	202210
	204020
	204220
	204020
	204220
	204020
	204220
	204020
	202210
	220000
	400000
RH	100100
	200040
	204004
	310010
	210010
	310010
	210010
	310010
	210010
	310010
	204004
	200040
	400000
LETTER	174120
	220000+LETEND
	220000
	060120
	.SIXBT	<36><34>'DELET'<37>
	020000
	060210
	.SIXBT	<36><34>'ADD'<37>
	020000
	060270
	.SIXBT	<36><34>'NODE'<37>
	020000
	060350
	.SIXBT	<36><34>'BRNCH'<37>
	020100	/ TO PNT  SCALE=00
	220005
	100470
	210000	/ RESISTOR
	201204
	202010
	202210
	202010
	202210
	202010
	202210
	202010
	201204
	610000
	020000
	220005	/ INDUCTOR
	100560	/ 500+30=530
	213000
	204002
	200005
	302001
	302201
	200205
	205202
	202000
	204002
	200005
	302001
	302201
	200205
	204202
	613000
	020000	/ CAPACITOR
	220005
	100640
	216400
	200010
	002400
	200220
	102400
	200010
	002400
	616400
	020000
	220005	/ VOLTAGE SOURCE
	100720
	212000
	206214
	206014
	306014
	306214
	005206
	202004
	302004
	202004
	005206
	612000
	020000
	220005
	101000
	212000	/ CURRENT SOURCE
	206214
	206014
	306014
	306214
	002400
	205000
	301603
	000006
	201603
	003400
	612000
	020000
	220064	/ GROUND BY DJS
	161060
	600000+G
	020120
	061150
	.SIXBT	<36><34>'WIRE'<37>
	020000
	061310
	.SIXBT	<36><34>'HORZ'<37>
	020000
	061370
	.SIXBT	<36><34>'VERT'<37>
	020000
	061530
	.SIXBT	<36><34>'OKAY'<37>
	020000
	061610
	.SIXBT	<36><34>'GRID'<35><37>
	160000
LETEND	0
/
/
LH	100100
	200054
	302020
	305000
	301210
	201210
	205000
	202020
	200010
	302020
	305000
	301210
	201210
	205000
	202020
	200054
	400000
LV	100100
	226000
	210004
	200012
	304002
	304202
	200212
	210204
	204000
	210004
	200012
	304002
	304202
	200212
	210204
	226000
	400000
CV	100100
	235400
	200020
	005000
	200240
	105000
	200020
	005000
	235400
	400000
CH	100100
	200073
	310000
	000012
	220000
	000212
	310000
	000012
	200073
	400000
VV	100100
	224000
	214230
	214030
	314030
	314230
	012214
	204010
	304010
	204010
	012214
	224000
	400000
VH	100100
	200050
	214030
	314030
	314230
	214230
	102014
	204010
	304010
	204010
	102014
	200050
	400000
IV	100100
	224000
	214230
	214030
	314030
	314230
	005000
	214000
	303206
	000014
	203206
	007000
	224000
	400000
IH	100100
	200050
	214030
	314030
	314230
	214230
	000012
	200030
	203206
	106000
	203006
	000016
	200050
	400000
X	110100
	002204
	206214
	120000
	206014
	000010
	306014
	020000
	306214
	502204
G	100100
	314000
	000214
	200030
	104204
	200220
	104004
	200010
	400000
/
VHVS	440000
HHVS	400100
/
/
/
SAVES	XX
	XX
	XX
	XX
TABLEN	.DSA	0
	.REPT 73
	.DSA	0
	174177
	.DSA	420000+GGRID
BEGIN	174137
	.BLOCK 500
TOVFOW	XX
	XX
	XX
	XX
NODET	170136
	.DSA	560004+BEGIN
	.BLOCK 300
GGRID	221770
	122010
	.BLOCK 555
NODE	LAC	STAR
	SZA
	JMP	YES
	LAC*	DISEND
	SAD	GBEFO
	JMP	.+5
	ADD	(2
	DAC*	DISEND
	DAC	ENDS3
	JMP	ION
	DZM	NNUM#
	IDRA
	TAD	(-2	/ TWO FOR LATE L.P. CYCLING
	DAC	DSAVE#
	IDSC
	TAD	(-1
	DAC	TDSAVE
	SPA
	JMP	NSUB
	LAC	DSAVE
	DAC	TDSAVE
	LAC*	TDSAVE
	SPA
	JMP	.+3
	ISZ	TDSAVE
	JMP	.-4
	LAC	TDSAVE
	DAC	EECOMP#
	LAC	TDSAVE
	TAD	(-1
	DAC	TDSAVE
	LAC*	TDSAVE
	RTL
	SZL
	JMP	.-6
	ISZ	TDSAVE
	LAC	TDSAVE
	DAC	SSCOMP#
	LAC	VERTM
	DAC	YPERM#
	LAC	HORZM
	DAC	XPERM#
	LAC	EECOMP
	DAC	DSAVE
	JMP	NDOWN
NSUB	LAW	17777
	DAC	DSAVE
	LAC	TDSAVE
	TAD	(-2
	DAC	PLACE
	LAC*	PLACE
	AND	(1777
	DAC	YPERM
	ISZ	PLACE
	LAC*	PLACE
	AND	(1777
	DAC	XPERM
	LAC	HORZM
	TAD	(-100
	CMA
	TAD	(1
	TAD	XPERM
	SMA
	JMP	.+4
	LAC	XPERM
	ADD	(LENGTH
	DAC	XPERM
	LAC	VERTM
	TAD	(-100
	CMA
	TAD	(1
	TAD	YPERM
	SMA
	JMP	.+4
	LAC	YPERM
	ADD	(LENGTH
	DAC	YPERM
NDOWN	LAC	XPERM
	DAC	HORZ1
	LAC	YPERM
	DAC	VERT1
	JMS	HIDDEN
	JMP	ION
NFIX	XX
	DZM	NMB#
	ISZ	NNUM
	LAC	(TABLEN
	DAC	PLACE
	ISZ	NMB
	LAC	NMB
	SAD	(25
	JMP	M6
	LAC*	PLACE
	SNA
	JMP	.+5
	LAC	PLACE
	ADD	(3
	DAC	PLACE
	JMP	NFIX+5
	LAC	XPERM
	DAC*	PLACE
	ISZ	PLACE
	LAC	YPERM
	DAC*	PLACE
	ISZ	PLACE
	LAC	DSAVE
	DAC*	PLACE
	JMS	OCTDEC
	LAC	TENS
	SZA
	JMP	.+7
	LAC	UNITS
	CLL
	ALS+14
	XOR	(3737
	DAC	WORD1#
	JMP*	NFIX
	CLL
	ALS+6
	XOR	UNITS
	ALS+6
	XOR	(37
	DAC	WORD1
	JMP*	NFIX
/
/
/
YES	LAC	TCROSS
	SZA
	JMP	.+3
	DZM	STAR
	JMP	M7
	LAC	HORZM
	SAD	HORZ2
	SKP
	JMP	.+10
	LAC	VERTM
	SAD	VERT2
	SKP
	JMP	.+4
	LAC	NNUM
	SZA
	JMP	ION
	LAC*	DISEND
	SAD	GBEFO
	SKP
	JMP	.+5
	TAD	(-2
	DAC*	DISEND
	DAC	ENDS3
	JMP	ION
	LAC	NNUM
	SZA
	JMP	.+7
	LAC	MODE
	SAD	(12
	JMS	NFIX
	LAC	MODE
	SAD	(14
	JMS	BFIX
	LAC	HORZM
	DAC	HORZ2
	LAC	VERTM
	DAC	VERT2
	LAC	FNODE
	DAC	PLACE
	LAC*	PLACE
	AND	(617777
	XOR	(020000
	DAC*	PLACE
	ISZ	PLACE
	LAC	(220000
	ADD	VERT2
	DAC*	PLACE
	ISZ	PLACE
	LAC	(060000
	ADD	HORZ2
	DAC*	PLACE
	ISZ	PLACE
	LAC	WORD1
	DAC*	PLACE
	LAC	MODE
	SAD	(12
	JMP	.+4
	ISZ	PLACE
	LAC	WORD2#
	DAC*	PLACE
	ISZ	PLACE
	LAC	(160000
	DAC*	PLACE
	LAC	PLACE
	DAC	TNODE
	ISZ	PLACE
	LAC	(560000
	ADD	DISEND
	DAC*	PLACE
	JMP	ION
/
/
/
/
BRANCH	LAC	STAR
	SZA
	JMP	YES
	LAC*	DISEND
	SAD	GBEFO
	JMP	.+5
	ADD	(2
	DAC*	DISEND
	DAC	ENDS3
	JMP	ION
	DZM	NNUM
	LAC	VERTM
	DAC	VERT1
	LAC	HORZM
	DAC	HORZ1
	IDSC		/ READ ASR
	TAD	(-1
	SMA
	JMP	CCLEAR
	AND	(17777
	DAC	TDSAVE
	DAC	DSAVE
	LAC	(TABLEB
	ADD	(1
	DAC	PLACE
	LAC*	PLACE
	SAD	DSAVE
	JMP	CCLEAR
	SNA
	JMP	.+5
	LAC	PLACE
	ADD	(4
	DAC	PLACE
	JMP	.-10
	JMS	SPART
	LAC	PART#
	SAD	(32
	JMP	CCLEAR
	JMS	HIDDEN
	JMP	ION
CCLEAR	LAC	DISPO
	DAC	TCNTR
	LAC*	DISPO
	AND	(617777
	XOR	(160000
	DAC*	DISPO
	DZM	TCROSS
	JMS	WINDUP
	JMP	ION
/
/
/
/
BFIX	XX
	ISZ	NNUM
	DZM	BNMB#
	LAC	PART
	CLL
	ALS+14
	DAC	TPART#
	ISZ	BNMB
	LAC	(TABLEB
	DAC	PLACE
	LAC*	PLACE
	SNA
	JMP	BINCR+4
	AND	(770000
	SAD	TPART
	SKP
	JMP	BINCR
	LAC*	PLACE
	AND	(777
	SAD	BNMB
	JMP	BFIX+7
BINCR	LAC	PLACE
	ADD	(4
	DAC	PLACE
	JMP	BFIX+12
	JMS	FORMB
	LAC	PART
	CLL
	ALS+3
	XOR	DIRECT
	ALS+11
	XOR	BNMB
	DAC*	PLACE
	ISZ	PLACE
	LAC	DSAVE
	DAC*	PLACE
	ISZ	PLACE
	LAW	17777
	DAC*	PLACE
	ISZ	PLACE
	DAC*	PLACE
	ISZ	PLACE
	DZM*	PLACE
	ISZ	PLACE
	DZM*	PLACE
	ISZ	PLACE
	DZM*	PLACE
	ISZ	PLACE
	DZM*	PLACE
	JMP*	BFIX
/
/
/
/
OCTDEC	XX
	LAC	NMB
	LMQ
	CLA!CLL
	DIV
	.DSA	12
	ADD	(60
	DAC	UNITS#
	LACQ
	SZA
	JMP	.+3
	DZM	TENS#
	JMP*	OCTDEC
	ADD	(60
	DAC	TENS
	JMP*	OCTDEC
/
/
DECOCT	XX
	LAC	TENS
	SZA
	JMP	.+5
	LAC	UNITS
	TAD	(-60
	DAC	NMB
	JMP*	DECOCT
	TAD	(-60
	CLL
	MUL
	.DSA	12
	LACQ
	ADD	UNITS
	TAD	(-60
	DAC	NMB
	JMP*	DECOCT
/
/
FORMB	XX
	LAC	BNMB
	DAC	NMB
	JMS	OCTDEC
	LAC	PART
	SAD	(20	/R
	LAC	(224000
	SAD	(22	/L
	LAC	(144000
	SAD	(24	/C
	LAC	(034000
	SAD	(26	/V
	LAC	(264000
	SAD	(30	/I
	LAC	(114000
	DAC	WORD1
	LAC	TENS
	SNA
	JMP	.+11
	XOR	WORD1
	DAC	WORD1
	LAC	UNITS
	CLL
	ALS+14
	XOR	(3737
	DAC	WORD2
	JMP*	FORMB
	LAC	UNITS
	XOR	WORD1
	DAC	WORD1
	LAC	(373737
	DAC	WORD2
	JMP*	FORMB
/
/
LCOMP	XX
	JMS	SPART
	LAC*	TDSAVE
	DAC	SWORD3#
	LAC	DIRECT
	SAD	(1
	JMP	.+4
	LAC	HHV
	DAC*	TDSAVE
	JMP*	LCOMP
	LAC	VHV
	DAC*	TDSAVE
	JMP*	LCOMP
/
/
SPART	XX
	LAC	(SUBTAG
	ADD	(1
	DAC	COMPAR#
	LAC	(20
	DAC	PART
	LAC	(1
	DAC	DIRECT
	LAC*	TDSAVE
	SAD*	COMPAR
	JMP	BDOWN
	ISZ	DIRECT
	ISZ	COMPAR
	LAC*	TDSAVE
	SAD*	COMPAR
	JMP	BDOWN
	LAC	PART
	ADD	(2
	DAC	PART
	ISZ	COMPAR
	JMP	SPART+6
BDOWN	LAC*	COMPAR
	AND	(017777
	DAC	SSCOMP
	ISZ	COMPAR
	LAC*	COMPAR
	AND	(017777
	DAC	EECOMP
	JMP*	SPART
/
/
VORS	XX
	LAW	17764
	DAC	COMPAR
	LAC	(1
	DAC	RVORS#
	LAC	(SUBTAG
	ADD	(1
	DAC	PLACE#
	LAC*	TDSAVE#
	SAD*	PLACE
	JMP	.+6
	ISZ	PLACE
	ISZ	COMPAR
	JMP	.-4
	DZM	RVORS
	JMP*	VORS
	LAC	TDSAVE
	TAD	(-1
	DAC	COMPAR
	LAC*	COMPAR
	AND	(160000
	SAD	(160000
	JMP*	VORS
	JMP	.-11
/
/
DATA	.DSA	0
PROTCT	.DSA	0
/
/
DELETE	LAC*	DISEND
	SAD	GBEFO
	JMP	.+5
	ADD	(2
	DAC*	DISEND
	DAC	ENDS3
	JMP	ION
	LAC	PROTCT
	SZA
	JMP	ION
	ISZ	PROTCT
	IDSC		/ READ ASR - WAS IT COMPONENT
	SMA
	JMP	NOSUBR	/ NO
	TAD	(-1
	AND	(17777
	DAC	TDSAVE
	DAC	DSAVE
	LAC	(14		/ DELETING A BRANCH
	DAC	TYPE#
	JMP	D2
NOSUBR	IDRA		/ EITHER WIRE OR TAG UNDER L.P.
	TAD	(-2	/ EXTRA MINUS FOR L.P. CYCLE
	DAC	TDSAVE
	DAC	DSAVE
	CMA
	TAD	(1
	TAD	(TOVFOW	/ IS IT IN TAG FILE
	SMA
	JMP	HNODE	/ NO! THEN WIRE
	JMS	FNODET	/RELATE TAG TO CIRCUIT
	ISZ	DATA
	LAC	TYPE	/WAS TAG FOR BRANCH
	SAD	(14
	JMP	D2	/ YES
	LAC	TDSAVE	/ WAS NODE A POINT
	SAD	(777777	/ AND NO REFERENCE
	JMP	D2+1	/ YES
HNODE	LAC	(12
	DAC	TYPE
	LAC*	TDSAVE
	SPA
	JMP	.+3
	ISZ	TDSAVE
	JMP	.-4
	LAC	TDSAVE
	DAC	EECOMP
	LAC	TDSAVE
	TAD	(-1
	DAC	TDSAVE
	LAC*	TDSAVE
	RTL
	SZL
	JMP	.-6
	ISZ	TDSAVE
	LAC	TDSAVE
	DAC	SSCOMP
	TAD	(-1
	DAC	TDSAVE
	ISZ	TDSAVE
	LAC*	TDSAVE
	AND	(577777
	DAC*	TDSAVE
	LAC	TDSAVE
	SAD	EECOMP
	JMP	.+3
	JMP	.-7
D2	JMS	LCOMP
	LAC	DATA
	SNA
	JMS	FDATA
	LAC	DATA
	SZA
	JMS	HLABEL
	JMP	ION
/
/
/
HLABEL	XX
	LAC	TYPE
	SAD	(14
	JMP	.+11
	LAC	ELABEL#
	TAD	(-1
	DAC	PLACE
	LAC*	PLACE
	DAC	SWORD1#
	LAC	(404037
	DAC*	PLACE
	JMP*	HLABEL
	LAC	SLABEL#
	ADD	(3
	DAC	PLACE
	LAC*	PLACE
	DAC	SWORD1
	LAC	(404040
	DAC*	PLACE
	ISZ	PLACE
	LAC*	PLACE
	DAC	SWORD2#
	LAC	(373737
	DAC*	PLACE
	JMP*	HLABEL
/
/
FNODET	XX
	LAC*	TDSAVE
	AND	(77
	SAD	(37
	JMP	.+3
	ISZ	TDSAVE
	JMP	.-5
	LAC	TDSAVE
	TAD	(-1
	DAC	TDSAVE
	LAC*	TDSAVE
	AND	(770000
	SAD	(060000
	SKP
	JMP	LBRAN
	ISZ	TDSAVE
	LAC*	TDSAVE
	CLL
	LRS+14
	DAC	TENS
	CLA
	LLS+6
	SAD	(37
	JMP	.+3
	DAC	UNITS
	JMP	.+4
	LAC	TENS
	DAC	UNITS
	DZM	TENS
	JMS	DECOCT
	LAC	NMB
	DAC	NNMB#
	LAC	TDSAVE
	TAD	(-3
	DAC	SLABEL
	ADD	(4
	DAC	ELABEL
	LAC	(TABLEN
	ADD	NMB
	ADD	NMB
	ADD	NMB
	TAD	(-3
	DAC	LPLACE#
	ADD	(2
	DAC	PLACE
	LAC*	PLACE
	DAC	TDSAVE
	DAC	DSAVE
	LAC	(12
	DAC	TYPE
	JMP*	FNODET
LBRAN	LAC	TDSAVE
	TAD	(-3
	DAC	SLABEL
	ADD	(5
	DAC	ELABEL
	LAC*	TDSAVE
	AND	(770000
	SAD	(220000	/R
	LAC	(20
	SAD	(140000	/L
	LAC	(22
	SAD	(030000	/C
	LAC	(24
	SAD	(260000	/V
	LAC	(26
	SAD	(110000	/I
	LAC	(30
	DAC	PART
	LAC*	TDSAVE
	AND	(77
	DAC	TENS
	ISZ	TDSAVE
	LAC*	TDSAVE
	AND	(770000
	CLL
	LRS+14
	DAC	UNITS
	SAD	(37
	SKP
	JMP	.+4
	LAC	TENS
	DAC	UNITS
	DZM	TENS
	JMS	DECOCT
	LAC	NMB
	DAC	BNMB
	LAC	(TABLEB
	DAC	PLACE
	LAC	PART
	CLL
	ALS+14
	DAC	TPART
LBRAN1	LAC*	PLACE
	AND	(770000
	SAD	TPART
	SKP
	JMP	.+5
	LAC*	PLACE
	AND	(777
	SAD	BNMB
	JMP	.+5
	LAC	PLACE
	ADD	(4
	DAC	PLACE
	JMP	LBRAN1
	LAC*	PLACE
	AND	(007000
	CLL
	LRS+11
	DAC	DIRECT
	LAC	PLACE
	DAC	LPLACE
	ISZ	PLACE
	LAC*	PLACE
	DAC	DSAVE
	DAC	TDSAVE
	LAC	(14
	DAC	TYPE
	JMP*	FNODET
/
/
/
FDATA	XX
	LAC	TYPE
	SAD	(14
	JMP	FBDATA
	DZM	NNMB
	LAC	(TABLEN
	ADD	(2
	DAC	PLACE
	ISZ	NNMB
	LAC*	PLACE
	SAD	EECOMP
	JMP	.+10
	LAC	NNMB
	SAD	(25
	JMP*	FDATA
	LAC	PLACE
	ADD	(3
	DAC	PLACE
	JMP	FDATA+10
	LAC	PLACE
	TAD	(-2
	DAC	LPLACE
	LAC	NNMB
	DAC	NMB
	JMS	OCTDEC
	LAC	TENS
	SZA
	JMP	.+7
	LAC	UNITS
	CLL
	ALS+14
	XOR	(3737
	DAC	WORD1
	JMP	.+7
	CLL
	ALS+6
	XOR	UNITS
	ALS+6
	XOR	(37
	DAC	WORD1
	LAC	(NODET
	DAC	PLACE
	LAC	WORD1
	ISZ	PLACE
	SAD*	PLACE
	SKP
	JMP	.-3
	LAC	PLACE
	TAD	(-3
	DAC	SLABEL
	ADD	(4
	DAC	ELABEL
	ISZ	DATA
	JMP*	FDATA
FBDATA	LAC	(TABLEB
	ADD	(1
	DAC	PLACE
	LAC*	PLACE
	SNA
	JMP*	FDATA
	SAD	DSAVE
	JMP	.+5
	LAC	PLACE
	ADD	(4
	DAC	PLACE
	JMP	.-10
	LAC	PLACE
	TAD	(-1
	DAC	LPLACE
	LAC*	LPLACE
	AND	(777
	DAC	BNMB
	JMS	FORMB
	LAC	(NODET
	DAC	PLACE
	LAC	WORD1
	ISZ	PLACE
	SAD*	PLACE
	SKP
	JMP	.-3
	ISZ	PLACE
	LAC	WORD2
	SAD*	PLACE
	SKP
	JMP	.-7
	LAC	PLACE
	TAD	(-4
	DAC	SLABEL
	ADD	(5
	DAC	ELABEL
	ISZ	DATA
	JMP*	FDATA
/
/
/
DFIX	XX
	LAC	PROTCT
	SZA
	JMP	.+3
	DZM	STAR
	JMP*	DFIX
	LAC	STAR
	SZA
	JMP	DDLETE
	LAC	TYPE
	SAD	(14
	JMP	BDFIX
	LAC	DATA
	SNA
	JMP	.+11
	LAC	SLABEL
	ADD	(3
	DAC	PLACE
	LAC	SWORD1
	DAC*	PLACE
	LAC	DSAVE
	SAD	(777777
	JMP	DWIND
	LAC*	SSCOMP
	XOR	(200000
	DAC*	SSCOMP
	LAC	SSCOMP
	SAD	EECOMP
	JMP	DWIND
	ISZ	SSCOMP
	JMP	.-7
BDFIX	LAC	SWORD3
	DAC*	DSAVE
	LAC	DATA
	SNA
	JMP	DWIND
	LAC	SLABEL
	ADD	(3
	DAC	PLACE
	LAC	SWORD1
	DAC*	PLACE
	ISZ	PLACE
	LAC	SWORD2
	DAC*	PLACE
	JMP	DWIND
DDLETE	LAC	TYPE
	SAD	(14
	JMP	DBDLET
	LAC	DATA
	SNA
	JMP	.+7
	LAC	DSAVE
	SAD	(777777
	SKP
	JMP	.+3
	DZM	BNMB
	SKP
	JMS	REMOVE
	LAC	DATA
	SNA
	JMP	.+7
	DZM*	LPLACE
	ISZ	LPLACE
	DZM*	LPLACE
	ISZ	LPLACE
	DZM*	LPLACE
	JMS	RLABEL
	JMS	UPDATE
	JMP	DWIND
DBDLET	LAC	DSAVE
	DAC	EECOMP
	DAC	SSCOMP
	JMS	REMOVE
	LAC	DATA
	SZA
	JMP	.+3
	JMS	UPDATE
	JMP	DWIND
	JMS	RLABEL
	LAC	LPLACE
	ADD	(2
	DAC	PLACE
	LAC*	PLACE
	DAC	VPNT#		/ ADDRESS OF COMPONENT'S VALUE
	ISZ	PLACE
	ISZ	PLACE
	LAC*	PLACE
	SNA
	JMP	.+5
	DAC*	LPLACE
	ISZ	PLACE
	ISZ	LPLACE
	JMP	.-6
	DZM*	LPLACE
	ISZ	LPLACE
	DZM*	LPLACE
	ISZ	LPLACE
	DZM*	LPLACE
	ISZ	LPLACE
	DZM*	LPLACE
	JMS	UPDATE
	LAC	VPNT	/ ADDRESS CARRIED IN AC
	JMS	RVALUE	/ GO DELETE VALUE
DWIND	DZM	DATA
	DZM	STAR
	DZM	TYPE
	DZM	PROTCT
	JMP*	DFIX
/
/
/
/  THIS SUBROUTINE REMOVES COMPONRNT'S VALUE FROM  TVALUE
/  TABLE AND UPDATES ANY NECESSARY POINTERS
/
RVALUE	XX
	DAC	VPNT
	DAC	PLACE
	DAC	COMPAR
	CMA
	SNA
	JMP*	RVALUE	/LOOK FOR CODE 777777 FOR
	ISZ	PLACE	/VALUE TERMINATOR
	LAC*	PLACE
	CMA
	SZA
	JMP	.-4
	ISZ	PLACE
	LAC*	PLACE	/WAS IT LAST VALUE IN THE TABLE
	SZA
	JMP	.+3
	DZM*	VPNT
	JMP*	RVALUE
	LAC	PLACE
	CMA
	TAD	(1
	TAD	VPNT
	DAC	NMB	/ NMB OF LOCATIONS MOVED
	LAC*	PLACE
	DAC*	VPNT
	ISZ	PLACE
	ISZ	VPNT
	LAC*	PLACE
	SZA
	JMP	.-5
	DZM*	VPNT
	LAC	(TABLEB
	ADD	(2
	DAC	PLACE
	LAC*	PLACE
	SNA
	JMP*	RVALUE
	CMA
	TAD	(1
	TAD	COMPAR
	SMA
	JMP	.+4
	LAC*	PLACE
	TAD	NMB
	DAC*	PLACE
	LAC	PLACE
	ADD	(4
	DAC	PLACE
	JMP	.-16
/
/
/
REMOVE	XX
	LAC	SSCOMP
	TAD	(-3
	DAC	SSCOMP
	ISZ	EECOMP
	LAC	SSCOMP
	DAC	NNMB
	LAC	EECOMP
	CMA
	TAD	(1
	TAD	SSCOMP
	DAC	BNMB
	LAC	EECOMP
	SAD	DISPO
	JMP	.+6
	LAC*	EECOMP
	DAC*	SSCOMP
	ISZ	EECOMP
	ISZ	SSCOMP
	JMP	.-7
	LAC	(160120
	DAC*	SSCOMP
	LAC	SSCOMP
	DAC	DISPO
	DAC	TCNTR
	JMS	WINDUP
	JMP*	REMOVE
/
/
/
RLABEL	XX
	LAC	ELABEL
	SAD	FNODE
	JMP	.+16
	LAC	SLABEL
	SAD	(NODET
	JMP	.+3
	LAC*	ELABEL
	DAC*	SLABEL
	ISZ	SLABEL
	ISZ	ELABEL
	LAC	ELABEL
	SAD	FNODE
	SKP
	JMP	.-7
	LAC*	ELABEL
	DAC*	SLABEL
	LAC*	SLABEL
	AND	(617777
	XOR	(160000
	DAC*	SLABEL
	LAC	SLABEL
	DAC	FNODE
	DAC	TNODE
	ISZ	SLABEL
	LAC	(560004
	ADD	DISPO
	DAC*	SLABEL
	JMP*	RLABEL
/
/
/
UPDATE	XX
	LAC	BNMB
	SNA
	JMP*	UPDATE
	LAW	17754
	DAC	COMPAR
	LAC	NNMB
	CMA
	TAD	(1
	DAC	NNMB
	LAC	(TABLEN
	ADD	(2
	DAC	PLACE
	LAC*	PLACE
	TAD	NNMB
	SPA
	JMP	.+4
	LAC*	PLACE
	TAD	BNMB
	DAC*	PLACE
	LAC	PLACE
	ADD	(3
	DAC	PLACE
	ISZ	COMPAR
	JMP	.-13
	LAC	(TABLEB
	ADD	(1
	DAC	PLACE
	LAC*	PLACE
	SNA
	JMP*	UPDATE
	TAD	NNMB
	SPA
	JMP	.+4
	LAC*	PLACE
	TAD	BNMB
	DAC*	PLACE
	LAC	PLACE
	ADD	(4
	DAC	PLACE
	JMP	.-14
/
/
/
/
/
DECIPH	LAC	TREAD+2
	SAD	(410320
	JMP	BRIGHT
	SAD	(420320
	JMP	DIM
	SAD	(512132
	JMP	RESET
	SAD	(416372
	JMP	ROSS
	SAD	(514320
	JMP	SAVER
	SAD	(436132
	JMP	GET
	LAC	(BUFF
	DAC	SDATA
	LAC	(TREAD+2
	JMS	UNPACK
	JMP	ECAP
BRIGHT	LAC	BEGIN
	AND	(7
	DAC	PLACE
	SAD	(7
	JMP	KBFIX
	LAC	NODET
	AND	(777770
	XOR	PLACE
	DAC	NODET
	ISZ	BEGIN
	JMP	KBFIX
DIM	LAC	BEGIN
	AND	(7
	DAC	PLACE
	SNA
	JMP	KBFIX
	LAC	BEGIN
	TAD	(-1
	DAC	BEGIN
	LAC	PLACE
	SAD	(1
	JMP	KBFIX
	LAC	NODET
	TAD	(-1
	DAC	NODET
	JMP	KBFIX
RESET	LAC	TREAD+3
	SAD	(342650
	SKP
	JMP	M3
	IOF
	LAC	BEGIN
	DAC	COMPAR
	LAC	(3000
	DAC	BEGIN
	CLL
	DZM	PLACE
	700601		/  STOP INTERRUPT
	SKP
	JMP	.+6
	LAC	PLACE
	ADD	(10
	DAC	PLACE
	SNL
	JMP	.-7
	LAC	COMPAR
	DAC	BEGIN
	LAW	17704
	DAC	COMPAR
	LAC	(TABLEN
	DAC	PLACE
	DZM*	PLACE
	ISZ	PLACE
	ISZ	COMPAR
	JMP	.-3
	LAC	(NODET
	DAC	TNODE
	DAC	FNODE
	LAC	NODET
	AND	(617777
	XOR	(160000
	DAC	NODET
	LAC	BEGIN
	AND	(617777
	XOR	(160000
	DAC	BEGIN
	LAC	(BEGIN
	DAC	DISPO
	DAC	TCNTR
	JMS	WINDUP
	LAC	(TABLEB
	DAC	PLACE
	LAW	17774
	DAC	COMPAR
	DZM*	PLACE
	ISZ	PLACE
	ISZ	COMPAR
	JMP	.-3
	LAC	(TVALUE
	DAC	PLACE
	DZM*	PLACE
	ISZ	PLACE
	DZM*	PLACE
	LAC	(BEGIN
	700704
	700606
	700042
	JMP	KBFIX
/
/
/
FILER	BEGIN
ROSS	JMS*	COPY	/ THIS STOPS DISPLAY
	JMP	.+2
	.DSA	MINIO
	JMP	KBFIX
MINIO	777777
/
/
/
SAVER	JMS	SAVE
	JMP	KBFIX
/
/
SAVE	XX
	LAC	PROTCT
	SZA
	JMP	M1	/ CONFIRM DELETION
	LAC	TCNTR
	SAD	DISPO
	SKP
	JMP	M2	/ CONFIRM LAST ADDITION
	LAC	TNODE
	SAD	FNODE
	SKP
	JMP	M4
	LAC	(SAVES
	DAC	PLACE
	LAC	DISPO
	TAD	(1
	CMA
	TAD	(1
	TAD	(TABLEN
	DAC*	PLACE
	ISZ	PLACE
	LAC	TNODE
	TAD	(2
	CMA
	TAD	(1
	TAD	(NODET
	DAC*	PLACE
	ISZ	PLACE
	LAC	(TABLEB
	DAC	COMPAR
	LAC*	COMPAR
	SNA
	JMP	.+3
	ISZ	COMPAR
	JMP	.-4
	LAC	COMPAR
	CMA
	TAD	(1
	TAD	(TABLEB
	DAC*	PLACE
	ISZ	PLACE
	LAC	(TVALUE
	DAC	COMPAR
	LAC*	COMPAR
	SNA
	JMP	.+3
	ISZ	COMPAR
	JMP	.-4
	LAC	COMPAR
	CMA
	TAD	(1
	TAD	(TVALUE
	DAC*	PLACE
	.INIT 6,1,PUNCH
	LAC	(SAVES
	DAC	PLACE
	DAC	PUNCH+3
	LAW	17774
	DAC	PUNCH+4
	JMS	PUNCH
	LAC	(TABLEN
	DAC	PUNCH+3
	LAC*	PLACE
	DAC	PUNCH+4
	JMS	PUNCH
	LAC	(NODET
	DAC	PUNCH+3
	ISZ	PLACE
	LAC*	PLACE
	DAC	PUNCH+4
	JMS	PUNCH
	LAC	(TABLEB
	DAC	PUNCH+3
	ISZ	PLACE
	LAC*	PLACE
	DAC	PUNCH+4
	SZA
	JMS	PUNCH
	LAC	(TVALUE
	DAC	PUNCH+3
	ISZ	PLACE
	LAC*	PLACE
	DAC	PUNCH+4
	SZA
	JMS	PUNCH
	.CLOSE 6
	JMP*	SAVE
GET	LAC	TREAD+3
	SAD	(406400
	SKP
	JMP	M3
	IOF
	LAC	(3000
	DAC	BEGIN
	CLL
	DZM	PLACE
	IDSI
	SKP
	JMP	.+6
	LAC	PLACE
	ADD	(10
	DAC	PLACE
	SNL
	JMP	.-7
	IDCF
	700042
	LAC	(SAVES
	DAC	PLACE
	DAC	READER+3
	.INIT 5,0,PUNCH
	LAW	17774
	DAC	READER+4
	JMS	READER
	LAC	(TABLEN
	DAC	READER+3
	LAC*	PLACE
	DAC	READER+4
	JMS	READER
	LAC	(NODET
	DAC	READER+3
	ISZ	PLACE
	LAC*	PLACE
	DAC	READER+4
	JMS	READER
	LAC	(TABLEB
	DAC	READER+3
	ISZ	PLACE
	LAC*	PLACE
	DAC	READER+4
	SZA
	JMS	READER
	LAC	(TVALUE
	DAC	READER+3
	ISZ	PLACE
	LAC*	PLACE
	DAC	READER+4
	SZA
	JMS	READER
	.CLOSE 5
	LAC	(SAVES
	DAC	PLACE
	LAC*	PLACE
	TAD	(-1
	CMA
	TAD	(TABLEN
	TAD	(-1
	DAC	DISPO
	DAC	TCNTR
	ISZ	PLACE
	LAC*	PLACE
	TAD	(-1
	CMA
	TAD	(NODET
	TAD	(-2
	DAC	TNODE
	DAC	FNODE
	JMS	WINDUP
	ISZ	PLACE
	LAC*	PLACE
	TAD	(-1
	CMA
	TAD	(TABLEB
	DAC	COMPAR
	DZM*	COMPAR
	ISZ	COMPAR
	DZM*	COMPAR
	ISZ	COMPAR
	DZM*	COMPAR
	ISZ	PLACE
	LAC*	PLACE
	TAD	(-1
	CMA
	TAD	(TVALUE
	DAC	PLACE
	DZM*	PLACE
	ISZ	PLACE
	DZM*	PLACE
	DZM	STAR
	DZM	PROTCT
	DZM	DATA
	DZM	TCROSS
	LAC	(BEGIN
	IDLA
	JMP	KBFIX
/
/
UNPACK	XX	/UNPACKS 5/7 ASCII TO 8 BITS
	DAC	STORE#	/ ONE CHAR. PER WORD
FURTH	LAC*	STORE	/ PACKED ADDRESS IN AC
	LMQ		/ UNPACKED ADDRESS IN SDATA
	CLA!CLL
	LLS+7		/ GET FIRST CHAR
	ADD	(200	/ ADD EXTRA BITS
	DAC*	SDATA	/ STORE & INCREMENT ADDRESS
	ISZ	SDATA
	SAD	(215	/ IS IT A CARRIAGE RETURN
	JMP*	UNPACK	/ FINISHED
	CLA
	LLS+7		/ GET 2ND CHAR
	ADD	(200
	DAC*	SDATA
	ISZ	SDATA
	SAD	(215
	JMP*	UNPACK
	CLA
	LLS+7		/ GET PART OF 3 CHAR
	DAC	HOLD#	/STORE TEMP
	ISZ	STORE	/ GET NEXT PACKED WORD
	LAC*	STORE
	LMQ
	CLA!CLL
	LLS+3		/ GET REST OF 3 CHAR
	ADD	HOLD	/GET FIRST PART OF 3 CHAR
	ADD	(200
	DAC*	SDATA
	ISZ	SDATA#
	SAD	(215
	JMP*	UNPACK
	CLA
	LLS+7		/ GET 4 CHAR
	ADD	(200
	DAC*	SDATA
	ISZ	SDATA
	SAD	(215
	JMP*	UNPACK
	CLA
	LLS+7		/ GET 5 CHAR
	ADD	(200
	DAC*	SDATA
	ISZ	SDATA
	SAD	(215
	JMP*	UNPACK
	ISZ	STORE	/ START ON NEXT SET OF 5
	JMP	FURTH	/ CHARS
/
/
/
/
/
/
/
FILE	.DSA	0
	.DSA	0
	.DSA	232203	/SRC
ECAP	DZM	LIST
	DZM	SAV
	LAC	(BUFF
	TAD	(-1
	DAC	TTPNT#
	ISZ	TTPNT
	LAC*	TTPNT
	SAD	(337	/  @
	JMP	ECAP1-4
	SAD	(314	/  L
	ISZ	LIST#
	SAD	(323	/  S
	ISZ	SAV#
	ISZ	TTPNT
	LAC*	TTPNT
	SAD	(337	/  @
	JMP	ECAP1-4
	SAD	(254	/  ,
	JMP	ECAP+5
	JMP	M3
	LAC	TTPNT
	DAC	DSAVE
	LAW	17772
	DAC	COMPAR
ECAP1	ISZ	TTPNT
	LAC*	TTPNT
	SAD	(215
	JMP	.+6
	AND	(77	/  SIXBT
	DAC*	TTPNT
	ISZ	COMPAR
	JMP	ECAP1
	JMP	.+12
	LAC	COMPAR
	SNA
	JMP	.+7
	SAD	(777772
	JMP	M3	/  NO NAME
	DZM*	TTPNT
	ISZ	TTPNT
	ISZ	COMPAR
	JMP	.-3
	LAW	17776
	DAC	TDSAVE
	LAC	(FILE
	DAC	PLACE
	LAW	17775
	DAC	COMPAR
	CLA!CLL
	ISZ	DSAVE
	ALS+6
	XOR*	DSAVE
	ISZ	COMPAR
	JMP	.-4
	DAC*	PLACE
	ISZ	PLACE
	ISZ	TDSAVE
	JMP	.-13
	JMP	MOVEON
/
PUNCH	XX
	.WRITE 6,4,PUNCH,20
	.WAIT 6
	JMP*	PUNCH
/
/
MASSGE	XX
	.INIT 4,1,START
PRINT	.WRITE 4,2,SM1,34
	.CLOSE 4
	.INIT 4,0,START
	DZM	PRINT+2
	JMP*	MASSGE
/
/
READER	XX
	.READ 5,4,READER,20
	.WAIT 5
	JMP*	READER
/
/
BUFF	.BLOCK 20
TREAD	.BLOCK 20
STAR	0
HORZ1	0
HORZ2	0
VERT1	0
VERT2	0
TCROSS	0
TWCNTR	0
TGRID	.DSA	GGRID+1
DISPO	300577
TCNTR	020000
TNODE	120000
FNODE	777611
START	ISZ	TGRID
	LAC	DISPO
	DAC*	TGRID
	ISZ	TGRID
	LAC	TCNTR
	DAC*	TGRID
	ISZ	TGRID
	LAC	TNODE
	DAC*	TGRID
	ISZ	FNODE
	JMP	.-12
	LAC	TGRID
	TAD	(-1
	DAC	TGRID
	LAC	(160000
	DAC*	TGRID
	ISZ	TGRID
	LAC	(400000
	ADD	(BEGIN
	DAC*	TGRID
	DZM	PRINT+2
	DZM	TGRID
	LAC	(BEGIN
	DAC	DISPO
	DAC	TCNTR
	LAC	(NODET
	DAC	FNODE
	DAC	TNODE
	CAL	0
	16
	IDSP
	LMONT
	CAL	0
	16
	IDVE
	BELOW
	CAL	0
	16
	IDSI	/STOP INTERRUPT
	BELOW+5
	CAL	0
	16
	IDHE
	BELOW
	JMS	WINDUP
	IDCF
	CAF
	700042
	.INIT 4,0,START
	LAC	(400000
	ISA
	LAC	(BEGIN
	IDLA		/ START DISPLAY
	SKP
KBFIX	JMS	LPON
	DBK
	.READ 4,2,TREAD,34
READTT	.WAITR 4,TTDISL
	.CLOSE 4
	JMS	LPOFF
	JMP	DECIPH
TTDISL	LAW	-100
	DAC	TIMER1#	/ THIS WAIT LOOP KEEPS I/O
	NOP		/ PROG INTERUPT WILL WORK
	NOP
	ISZ	TIMER1
	JMP	.-3
	JMP	READTT
MOVEON	DBK
	.INIT 3,1,START
	.ENTER 3,FILE
	JMP*	DECODE
/
/
/
BELOW	DAC	ACSAVE#	/ RING TELETYPE BELL
	LAC	(207
	TLS
	TSF
	JMP	.-1
	TCF
	LAC	(NODET
	IDCF
	IDLA
	LAC	ACSAVE
	700042
	DBR
	JMP*	0
/
/
SM1	.ASCII	'     CONFIRM DELETION'<215>
SM2	.ASCII	'     PUT LP TO ADD TO CONFIRM '
	.ASCII	'LAST ADDITION & TYPE S'<215>
SM3	.ASCII	'     WHAT?'<215>
SM4	.ASCII	'     PUT LP TO ADD TO CON'
	.ASCII	'FIRM LASR ADDITION & TYPE S'<215>
SM5	.ASCII	'     DISPLAY FILE OVERFLOW'<215>
SM6	.ASCII	'     MAXIMUM NUMBER OF NODES IS 20'<215>
SM7	.ASCII	'     NODE OR BRANCH IS NOT INDICATED'<215>
/
M1	LAC	(SM1
	JMP	MERR
M2	LAC	(SM2
	JMP	MERR
M3	LAC	(SM3
	JMP	MERR
M4	LAC	(SM4
MERR	DAC	PRINT+2
	DBK
	JMS	MASSGE
	JMP	KBFIX
M5	LAC	(SM5
	JMP	SMESS
M6	LAC	(SM6
	JMP	SMESS
M7	LAC	(SM7
SMESS	DAC	PRINT+2
/
ION	LAC	MODE	/ IF MODE IS DELETE
	SAD	(4	/ RESTART DISPLAY
	JMP	.+5
	LAC	VERTM	/ IF LP AT CONTROL CHAR
	TAD	(-61	/ RESTART DISPLAY
	SMA
	JMP	TMESS-1
	LAC	(NODET	/ RESTART AT FILE FOR TAGS
	IDCF
	IDLA
	SKP
	IDRS		/ CONTINUE DISPLAY OP.
TMESS	LAC	PRINT+2
	SNA
	JMP	GOION
	LAC	0
	DAC	ZERO#
	JMS	LPOFF
	CAF
	700042		/ ION
	JMS	MASSGE
	IOF
	LAC	ZERO
	DAC	0
	JMS	LPON
GOION	LAC	ACSAVE
	700042		/ ION
	DBR
	JMP*	0
/
/
/
LMONT	DAC	ACSAVE
	IDRC		/ READ X & Y COORDINATES
	DAC	COORD#
	AND	(777
	CLL
	RAL
	DAC	VERTM#
	LAC	COORD
	AND	(777000
	CLL
	LRS+10
	DAC	HORZM#
	LAC	VERTM
	TAD	(-105
	SMA
	JMP	.+5
	LAC	VERTM
	SMA
	JMP	LMONT1
	DZM	TGRID
	JMP	ADDER
LMONT1	JMS	FHORZ
	LAC	DISPO
	SAD	TCNTR
	JMP	LMONT2
	LAC	DTEL
	SAD	(46
	JMP	LMONT3	/@STAR
	SAD	(10
	JMP	LMONT2
	LAC	FNODE
	SAD	TNODE
	JMP	.+3
	JMS	FIXSYM
	JMP	LMONT2
	JMS	BKWRK
	JMP	LMONT2
LMONT3	DZM	TGRID
	ISZ	STAR
	JMP	ION
LMONT2	LAC	DTEL
	SAD	(10	/GRID
	JMP	LMONT4
	DZM	TGRID
	LAC	DTEL
	SAD	(46
	SKP
	JMP	.+4
	ISZ	STAR
	JMS	DFIX
	JMP	ION
	LAC	MODE
	SAD	(4	/DELETE
	JMS	DFIX
	LAC	(4
	DAC	SDTEL#
LMONT5	LAC	DTEL
	SAD	SDTEL
	DAC	MODE
	SAD	SDTEL
	JMP	LMONT7
	LAC	SDTEL
	ADD	(2
	DAC	SDTEL
	SAD	(16
	SKP
	JMP	LMONT5
	ISZ	SDTEL
	ISZ	SDTEL
LMONT6	LAC	DTEL
	SAD	SDTEL
	DAC	COMP
	SAD	SDTEL
	JMP	ION
	LAC	SDTEL
	ADD	(2
	DAC	SDTEL
	SAD	(36
	SKP
	JMP	LMONT6
	LAC	DTEL
	SAD	(40
	SKP
	JMP	.+4
	LAC	(2	/HORZ
	DAC	DIRECT
	JMP	ION
	LAC	(1
	DAC	DIRECT
	JMP	ION
LMONT4	LAC	TGRID
	SZA
	JMP	ION
	ISZ	TGRID
	LAC*	D#ISEND
	SAD	GBEFO
	JMP	.+5
	ADD	(2
	DAC	ENDS3
	DAC*	DISEND
	JMP	ION
	TAD	(-2
	DAC	ENDS3
	DAC*	DISEND
	JMP	ION
/
BKWRK	XX
	LAC	STAR
	SZA
	JMP	BK1
	LAC	TCROSS
	SNA
	JMP	BK1
	DZM	TCROSS
	LAC	DISPO
	DAC	TCNTR
	LAC*	TCNTR
	AND	(617777
	XOR	(160000
	DAC*	TCNTR
	JMS	WINDUP
BK1	LAC	DISPO
	SAD	(BEGIN
	JMP	.+5
	LAC*	DISPO
	AND	(763777
	DAC*	DISPO
	JMP	.+5
	LAC*	DISPO
	AND	(763777
	XOR	(014000
	DAC*	DISPO
	LAC	TCNTR
	DAC	DISPO
	DZM	TWCNTR
	DZM	VERT1
	DZM	HORZ1
	LAC	TNODE
	DAC	FNODE
	DZM	STAR
	JMP*	BKWRK
/
/
/
LPOFF	XX
	LAC	LETTER
	AND	(763777
	DAC	LETTER
	LAC	BEGIN-2
	AND	(763777
	DAC	BEGIN-2
	LAC	BEGIN
	AND	(763777
	DAC	BEGIN
	LAC	NODET
	AND	(773777
	DAC	NODET
	JMP*	LPOFF
/
/
LPON	XX
	LAC	LETTER
	XOR	(014000
	DAC	LETTER
	LAC	BEGIN-2
	XOR	(014000
	DAC	BEGIN-2
	LAC	BEGIN
	XOR	(014000
	DAC	BEGIN
	LAC	MODE
	SAD	(4
	SKP
	JMP*	LPON
	LAC	NODET
	XOR	(004000
	DAC	NODET
	JMP*	LPON
/
/
/
FHORZ	XX
	LAC	HORZM
	TAD	(-104
	DAC	THORZM#
	LAC	(1
	DAC	DTEL#
LLOOP	ISZ	DTEL
	LAC	THORZM
	TAD	(-60
	DAC	THORZM
	SMA
	JMP	LLOOP
	LAC	DTEL
	ADD	DTEL
	DAC	DTEL
	SAD	(4
	JMP*	FHORZ
	SAD	(6
	JMP*	FHORZ
	SAD	(46
	JMP	.+4
	ADD	(2
	DAC	DTEL
	JMP*	FHORZ
	LAC	(10
	DAC	DTEL
	JMP*	FHORZ
/
FIXSYM	XX
	LAC	TNODE
	DAC	FNODE
	LAC	DISPO
	DAC	TCNTR
	LAC*	TCNTR
	AND	(617777
	XOR	(160000
	DAC*	TCNTR
	DZM	TCROSS
	DZM	STAR
	JMS	WINDUP
	JMP*	FIXSYM
/
LMONT7	LAC	MODE
	SAD	(4
	LAC	(JMP DELETE
	SAD	(6
	LAC	(JMP ADDER
	SAD	(12
	LAC	(JMP NODE
	SAD	(14
	LAC	(JMP BRANCH
	DAC	LMONT1-1
	LAC	MODE
	SAD	(4
	JMP	.+5
	LAC	NODET
	AND	(773777
	DAC	NODET
	JMP	ION
	LAC	NODET
	AND	(773777
	XOR	(004000
	DAC	NODET
	JMP	ION
/
/
MODE	.DSA	6
COMP	.DSA	26
DIRECT	.DSA	1
/
/
/
/
ADDER	LAC	COMP
	SAD	(34	/WIRE
	JMP	WIRE
	JMP	CMPNT
/
/
/
/
/
WIRE	LAC	STAR
	SNA
	SKP
	JMP	.+7
	LAC	VERTM
	DAC	VERT1
	LAC	HORZM
	DAC	HORZ1
	JMS	HIDDEN
	JMP	ION
	LAC	VERTM
	SAD	VERT2
	SKP
	JMP	.+4
	LAC	HORZM
	SAD	HORZ2
	JMP	ION
	LAC	VERTM
	DAC	VERT2
	LAC	HORZM
	DAC	HORZ2
	LAC	TCROSS
	SZA
	JMS	CTCROS
	DZM	VDONE#
	DZM	HDONE#
	DZM	HFIX#
	DZM	VFIX#
	LAC	TWCNTR
	CMA
	TAD	(1
	TAD	TCNTR
	DAC	TCNTR
	DZM	TWCNTR
	LAC	ZEROV#
	SNA
	JMP	.+6
	DZM	ZEROV
	LAC*	TCNTR
	AND	(617777
	XOR	(100000
	DAC*	TCNTR
	LAC	DIRECT
	SAD	(1
	JMP	LWIRE1
LWIRE2	ISZ	HDONE
	LAC	(200000	/VFORMAT
	DAC	TFORMAT#
	LAC	HORZ1
	CMA
	TAD	(1
	TAD	HORZ2
	SNA
	JMP	WFIX
	SMA
	DAC	LENTH#
	SMA
	JMP	LWIRE3
	LAC	HORZ2
	CMA
	TAD	(1
	TAD	HORZ1
	DAC	LENTH
	LAC	TFORMAT#
	ADD	(200
	DAC	TFORMAT
	JMP	LWIRE3
LWIRE1	ISZ	VDONE
	LAC	(200000	/VFORMAT
	DAC	TFORMAT
	LAC	VERT1
	CMA
	TAD	(1
	TAD	VERT2
	SNA
	JMP	WFIX
	SMA
	DAC	LENTH
	SMA
	JMP	LWIRE3
	LAC	VERT2
	CMA
	TAD	(1
	TAD	VERT1
	DAC	LENTH
	LAC	TFORMAT
	ADD	(100000
	DAC	TFORMAT
LWIRE3	LAC	LENTH
	LMQ
	CLA!CLL
	DIV
	.DSA	376
	DAC	REMAIN#
	SNA
	JMP	.+4
	LACQ
	DAC	WCNTR#
	JMP	LWIRE4
	LAC	(376
	DAC	REMAIN
	LACQ
	TAD	(-1
	DAC	WCNTR
LWIRE4	LAC	TWCNTR
	ADD	(1
	ADD	WCNTR
	DAC	TWCNTR
	LAC	DIRECT
	SAD	(1
	JMP	LWIRE5
LWIRE6	LAC	VDONE
	SZA
	JMP	LWIRE5+3
	LAC	WCNTR
	CMA
	DAC	DTEL
	LAC	TFORMAT
	ADD	(177
	DAC	TFORMAT
	ISZ	DTEL
	SKP
	JMP	.+5
	ISZ	TCNTR
	LAC	TFORMAT
	DAC*	TCNTR
	JMP	.-6
	LAC	TFORMAT
	TAD	(-177
	DAC	TFORMAT
	LAC	REMAIN
	LMQ
	CLA!CLL
	DIV
	.DSA	2
	LACQ
	ADD	TFORMAT
	ISZ	TCNTR
	DAC*	TCNTR
	LAC	DIRECT
	SAD	(1
	JMP	WIREO
	JMP	LWIRE1
LWIRE5	LAC	HDONE
	SZA
	JMP	LWIRE6+3
	LAC	WCNTR
	CMA
	DAC	DTEL
	LAC	TFORMAT
	ADD	(77400
	DAC	TFORMAT
	ISZ	DTEL
	SKP
	JMP	.+5
	ISZ	TCNTR
	LAC	TFORMAT
	DAC*	TCNTR
	JMP	.-6
	LAC	TFORMAT
	TAD	(-77400
	DAC	TFORMAT
	LAC	REMAIN
	LMQ
	CLA!CLL
	DIV
	.DSA	2
	LACQ
	CLQ
	LLS+10
	ADD	TFORMAT
	ISZ	TCNTR
	DAC*	TCNTR
	LAC	DIRECT
	SAD	(1
	JMP	LWIRE2
WIREO	LAC*	TCNTR
	ADD	(400000
	DAC*	TCNTR
	ISZ	TWCNTR
	ISZ	TCNTR
	LAC	(160120
	DAC*	TCNTR
ZWIRE	JMS	WINDUP
	JMP	ION
/
WFIX	LAC	DIRECT
	SAD	(1
	JMP	LWFIX2
	LAC	VDONE
	SNA
	ISZ	HFIX
	SNA
	JMP	LWIRE1
	LAC	HFIX
	SNA
	JMP	WIREO
	JMP	LWFIX3
LWFIX2	LAC	HDONE
	SNA
	ISZ	VFIX
	SNA
	JMP	LWIRE2
	LAC	VFIX
	SNA
	JMP	WIREO
LWFIX3	ISZ	ZEROV
	LAC*	TCNTR
	AND	(617777	/VECT
	XOR	(160000	/TO SUB
	DAC*	TCNTR
	JMP	ZWIRE
/
CTCROS	XX
	DZM	TCROSS
	LAC	TCNTR
	TAD	(-2
	DAC	TCNTR
	LAC*	TCNTR
	AND	(617777	/SUB TO
	XOR	(100000	/VECT
	DAC*	TCNTR
	JMP*	CTCROS
/
/
/
HIDDEN	XX
	LAC	DISPO
	DAC	TCNTR
	LAC*	DISPO
	AND	(603777
	XOR	(030000	/ LP OFF & MODE SET TO POINT
	DAC*	DISPO
	ISZ	TCNTR
	LAC	(220000	/PFORM1
	ADD	VERT1
	DAC*	TCNTR
	ISZ	TCNTR
	LAC	(162000	/INTENSITY BIT
	ADD	HORZ1
	DAC*	TCNTR
LHIDE2	LAC	MODE
	SAD	(12
	JMP	.+7	/NODE
	SAD	(14
	JMP	.+5	/BRANCH
	LAC	COMP
	SAD	(34
	SKP
	JMP*	HIDDEN
	LAC	(1
	DAC	TCROSS
	ISZ	TCNTR
	LAC	CROSS
	DAC*	TCNTR
	ISZ	TCNTR
	LAC	(160120	/SCALE
	DAC*	TCNTR
	JMS	WINDUP
	JMP*	HIDDEN
/
/
/
/
LENGTH=200
CMPNT	LAC	VERTM
	DAC	VERT1
	LAC	HORZM
	DAC	HORZ1
	JMS	HIDDEN
	LAC	(SUBTAG
	ADD	COMP
	ADD	DIRECT
	TAD	(-20
	DAC	SUBTAG
	ISZ	TCNTR
	LAC*	SUBTAG
	DAC*	TCNTR
	ISZ	TCNTR
	LAC	(160120	/SCALE
	DAC*	TCNTR
	JMS	WINDUP
	JMP	ION
SUBTAG	XX
	.DSA	600000+RV
	.DSA	600000+RH
	.DSA	600000+LV
	.DSA	600000+LH
	.DSA	600000+CV
	.DSA	600000+CH
	.DSA	600000+VV
	.DSA	600000+VH
	.DSA	600000+IV
	.DSA	600000+IH
	.DSA	600000+G
	.DSA	600000+G
VHV	.DSA	700000+VHVS
HHV	.DSA	700000+HHVS
CROSS	.DSA	600000+X
/
/
/
/
WINDUP	XX
	LAC	(TOVFOW
	TAD	(-5
	CMA
	ADD	TCNTR
	SMA
	JMP	M5
	LAC	TCNTR
	ADD	(1
	DAC	DISEND
	LAC	END
	DAC*	DISEND
	ISZ	DISEND
	LAC	ENDS1
	DAC*	DISEND
	ISZ	DISEND
	LAC	ENDS2
	DAC*	DISEND
	ISZ	DISEND
	LAC	ENDS3
	DAC*	DISEND
	ISZ	TNODE
	LAC	(560000
	ADD	DISEND
	DAC*	TNODE
	DAC	ENDS4
	LAC	TNODE
	TAD	(-1
	DAC	TNODE
	JMP*	WINDUP
/
END	.DSA	600000+LETTER
ENDS1	.DSA	160000
ENDS2	.DSA	400000+NODET
ENDS3	.DSA	400000+BEGIN
ENDS4	.DSA	560004+BEGIN
GBEFO	.DSA	400000+BEGIN
/
/
/
	.END TSTART