/INITIALIZE SOFTWARE LEVEL INTERRUPT
/   SUBROUTINE
/EXECUTION TIME: 69 (4), 73 (6), 74 (5),
/                 76 (7) MICROSECONDS
/CALLING SEQUENCE:
/   CALL ISLI(LEVEL,HANDLER,ERROR)
/   LEVEL:  4-7 SOFTWARE LEVEL NUMBER
/   HANDLER:  PARAMETERLESS FORTRAN IV
/                SUBROUTINE NAME
/                (INTERRUPT HANDLER)
/   ERROR=0:  NO ERROR
/        =1:  ILLEGAL LEVEL REQUESTED
/        =7:  API IS DISABLED
/             (ISLI CANNOT PROCEED)
	.TITLE ISLI
	.GLOBL ISLI
	.GLOBL %SOFT4,%SOFT5
	.GLOBL %SOFT6,%SOFT7
	.GLOBL %4SOFT,%5SOFT
	.GLOBL %6SOFT,%7SOFT
ISLI	0
	ISZ ISLI
	LAC* ISLI
	DAC LEVEL
	SPA
	LAC* LEVEL  /INDIRECT
	DAC LEVEL	/REQUESTED LEVEL
	ISZ ISLI	/BUMP TO HANDLER
	LAC* ISLI
	SMA
	JMP .+3
	DAC ERROR	/INDIRECT
	LAC* ERROR
	LMQ	/USER ADDRESS
	ISZ ISLI
	LAC* ISLI
	DAC ERROR
	SPA
	LAC* ERROR  /INDIRECT
	DAC ERROR	/ERROR LOCATION
	DZM* ERROR	/ERROR=0
	ISZ ISLI	/BUMP TO EXIT
	LAC (400000
	SPI
	JMP ERROR7	/API IS OFF
	LAC* LEVEL
	TAD (-4	/LEVEL-4
	SNA
	JMP ISLI4	/LEVEL 4 REQUESTED
	SPA
	JMP ERROR1	/LEVEL<4
	TAD (-2	/LEVEL-6
	SNA
	JMP ISLI6	/LEVEL 6 REQUESTED
	SPA
	JMP ISLI5	/LEVEL 5 REQUESTED
	TAD (-1	/LEVEL-7
	SZA
	JMP ERROR1	/LEVEL>7
		/LEVEL 7 REQUESTED
ISLI7	LACQ
	DAC* %SOFT7	/USER ADDR.
	LAC %7SOFT
	DAC* (115	/.SCOM+15=%7SOFT
	LAC (400400
	ISA	/REQUEST SOFTWARE 7
	JMP* ISLI
ISLI6	LACQ
	DAC* %SOFT6	/USER ADDR.
	LAC %6SOFT
	DAC* (114	/.SCOM+14=%6SOFT
	LAC (401000
	ISA	/REQUEST SOFTWARE 6
	JMP* ISLI
ISLI5	LACQ
	DAC* %SOFT5	/USER ADDR.
	LAC %5SOFT
	DAC* (113	/.SCOM+13=%5SOFT
	LAC (402000
	ISA	/REQUEST SOFTWARE 5
	JMP* ISLI
ISLI4	LACQ
	DAC* %SOFT4	/USER ADDR.
	LAC %4SOFT
	DAC* (112	/.SCOM+12=%4SOFT
	LAC (404000
	ISA	/REQUEST SOFTWARE 4
	JMP* ISLI
ERROR1	ISZ* ERROR	/ILL. LEVEL
	JMP* ISLI
ERROR7	LAC (7
	DAC* ERROR	/API IS OFF
	JMP* ISLI
ERROR
LEVEL
	.END