/INITIALIZE (PDP-9 ONLY) SUBROUTINE
/EXECUTION TIME:  17 MICROSECONDS
/CALLING SEQUENCE:  CALL INIT9
	.TITLE INIT9
	.GLOBL INIT9,%HALTS
INIT9	0
	CAF	/CLEAR ALL INTERRUPTS
	LAC* (112
	DAC %HALTS	/SOFT. HALT
	LAC (400000
	ISA	/ENABLE API
	JMP* INIT9
%HALTS
	.EJECT
/SOFTWARE INTERRUPT HANDLER
/EXECUTION TIME:  30 MICROSECONDS +
/                 USER SUBROUTINE
	.GLOBL %SOFT4,%SOFT5
	.GLOBL %SOFT6,%SOFT7
	.GLOBL %4SOFT,%5SOFT
	.GLOBL %6SOFT,%7SOFT
%4SOFT	0
	EEM	/ENABLE EXTEND MODE
	DAC KPAC4	/SAVE AC
	LACQ
	DAC KPMQ4	/SAVE MQ
	LAC %HALTS
	DAC* (112	/DISABLE 4
	JMS* %SOFT4	/EXEC. USER 4
	LAC KPMQ4
	LMQ	/RESTORE MQ
	LAC KPAC4	/RESTORE AC
	DBR
	JMP* %4SOFT	/RELEASE 4
KPAC4
KPMQ4
%5SOFT	0
	EEM	/ENABLE EXTEND MODE
	DAC KPAC5	/SAVE AC
	LACQ
	DAC KPMQ5	/SAVE MQ
	LAC %HALTS
	DAC* (113	/DISABLE 5
	JMS* %SOFT5	/EXEC. USER 5
	LAC KPMQ5
	LMQ	/RESTORE MQ
	LAC KPAC5	/RESTORE AC
	DBR
	JMP* %5SOFT	/RELEASE 5
KPAC5
KPMQ5
%6SOFT	0
	EEM	/ENABLE EXTEND MODE
	DAC KPAC6	/SAVE AC
	LACQ
	DAC KPMQ6	/SAVE MQ
	LAC %HALTS
	DAC* (114	/DISABLE 6
	JMS* %SOFT6	/EXEC. USER 6
	LAC KPMQ6
	LMQ	/RESTORE MQ
	LAC KPAC6	/RESTORE AC
	DBR
	JMP* %6SOFT	/RELEASE 6
KPAC6
KPMQ6
%7SOFT	0
	EEM	/ENABLE EXTEND MODE
	DAC KPAC7	/SAVE AC
	LACQ
	DAC KPMQ7	/SAVE MQ
	LAC %HALTS
	DAC* (115	/DISABLE 7
	JMS* %SOFT7	/EXEC. USER 7
	LAC KPMQ7
	LMQ	/RESTORE MQ
	LAC KPAC7	/RESTORE AC
	DBR
	JMP* %7SOFT	/RELEASE 7
KPAC7
KPMQ7
%SOFT4
%SOFT5
%SOFT6
%SOFT7
	.END