SUBROUTINE CSM6
C	OPTION TO OUTPUT UPDATED MODEL
	INTEGER OU,TEST4
	LOGICAL RSAC
	DIMENSION MTRX(75,5),NOFG(3),F(3,11),PAR(75,3)
	COMMON REALS(395),INTS(547)
	COMMON/EXTRA2/TY(30)
	EQUIVALENCE (INTS(1),MTRX(1,1)),(INTS(421),NOFG(1))
	EQUIVALENCE (INTS(528),TEST4)
	EQUIVALENCE (REALS(81),PAR(1,1)),(REALS(306),F(1,1))
	IF (RSAC(11)) GO TO 20
C	LINE PRINTER/CARD PUNCH OUTPUT
	WRITE(8,10)
10	FORMAT(1H1)
	OU=8
	GO TO 40
C	PAPER TAPE OUTPUT
20	OU=6
30	FORMAT(1H )
C	OUTPUT CONFIGURATION SPECIFICATIONS
40	DO 80 I=1,75
	J=MTRX(I,1)
	IF (J.LE.0) GO TO 80
	K=4
	DO 50 L=1,3
	IF (MTRX(I,K).NE.0) GO TO 60
50	K=K-1
	WRITE(OU,70) I,TY(J)
	GO TO 80
60	WRITE(OU,70) I,TY(J),(MTRX(I,L),L=2,K)
70	FORMAT(3X,I2,5X,A1,3(6X,I3))
80	CONTINUE
	WRITE(OU,30)
C	OUTPUT INITIAL CONDITIONS AND PARAMETERS
	DO 130 I=1,75
	J=MTRX(I,1)
	IF (J.LE.0) GO TO 130
	K=3
	DO 100 L=1,3
	IF (PAR(I,K).NE.0.0) GO TO 110
100	K=K-1
	GO TO 130
110	IF (J.EQ.20.OR.J.EQ.21.OR.J.EQ.26) K=1
C	THE PRECEDING STATEMENT DELETES TEMPORARY DELAY PARAMETERS
C	   GENERATED BY T (TIME PULSE), U (UNIT DELAY), AND 
C	   Z (ZERO ORDER HOLD) BLOCKS DURING EXECUTION (OF CSM11)
	WRITE(OU,120) I,(PAR(I,L),L=1,K)
120	FORMAT(3X,I2,1X,3(1X,G13.6))
130	CONTINUE
	WRITE(OU,30)
C	OUTPUT FUNCTION GENERATORS
	IF (TEST4.EQ.1) GO TO 170
	DO 160 I=1,3
	J=NOFG(I)
	IF (J.LE.0.OR.MTRX(J,1).NE.6) GO TO 160
C	IT IS CONFIRMED THAT THE BLOCK IS A FUNCTION GENERATOR
	WRITE(OU,140) J,(F(I,K),K=1,11)
140	FORMAT(I3,9X,5(1X,G11.4)/6(1X,G11.4))
160	CONTINUE
	WRITE(OU,30)
170	IF (OU.EQ.8) WRITE(8,180)
180	FORMAT(//1H1)
	RETURN
	END