/COPYRIGHT 1970, DIGITAL EQUIPMENT CORP., MAYNARD, MASS.
/EDIT 5   10-13-70
       .TITLE PAUSE
/OBJECT TIME PAUSE STATEMENT PROCESSOR.
/CALLING SEQUENCE--LAC   NUMBER TO BE PRINTED.
/                  JMS*  .PA
	/IF BACKGROUND-FOREGROUND MONITOR DEFINE BF
       .GLOBL .PA,.SP
	.GLOBL PAUSE
	.IFDEF BF
	.GLOBL PACPF
	.ENDC
PAUSE=.
.PA    CAL    0
       JMS*   .SP            /PRINT MESSAGE.
       .DSA   PA1            / CONTROL RETURN
       LAW    120            /P
       LAW    101            /A
       LAW    125            /U
       LAW    123            /S
       LAW    105            /E
       LAW    040            /BLANK
	.IFUND BF
       JMP    .              /HALT EXECUTION UNTIL ^P
	.ENDC
	.IFDEF	BF
/DETERMINE IF BG OR FG IN BF ENVIRONMENT
/.SCOM+26=0 IF FG,=1 IF BG
PACYC	LAC*	PACPF		/CHECK ^P FLAG
	SNA			/NOT = IF ON
	JMP	PA2		/NO
	DZM*	PACPF		/CLEAR FLAG AND EXIT
	JMP*	.PA		/EXIT
PA2	LAC*	PA3		/IF IN FG, DO AN .IDLEC
	SZA
	JMP	PACYC		/RECYCLE AND AWAIT ^P
	CAL	1000		/IDLEC
		17
	JMP	PACYC		/RECYCLE AND AWAIT ^P
PA3	126			/.SCOM+26
	.ENDC
PA1    JMP*   .PA            /RETURN TO PROGRAM--ASSIGNED TO INT. GLOBL PAUSE
       .END