5 *NAME WCHILL
  100 REM Windchill computation program
  110 REM
  120 REM This program computes the windchill, in degrees F
  130 REM given the wind speed in mph. The following relation is
  140 REM used to compute the windchill (taken from "Climatology:
  150 REM Selected Applications" by John E. Oliver, V.H. Winston
  160 REM and Sons, 1981.
  170 REM
  180 REM k = ( sqr(v*100) - v + 10.5 ) * (33 - T)
  190 REM
  200 @%=&00020108
  210 CLS
  220 READ NTH
  230 DIM TH(NTH), M$(NTH)
  240 FOR I=1 TO NTH
  250   READ TH(I),M$(I)
  260 NEXT I
  270 DATA 6
  280 DATA 600,"Cool",1000,"Cold",1200,"Very cold",1400,"Bitter cold",2000,"Exposed flesh freezes - Danger",4000,"Exposed flesh freezes in 1 minute - Severe danger"
  290 CLS
  300 PRINT
  310 INPUT "Temperature (F) [-80 to 60] ";TF
  320 IF TF<-80 THEN TF=-80
  330 IF TF>60 THEN TF=60
  340 INPUT "Wind Speed (mph) ";VM
  350 CLS
  360 TC=(TF-32)*5/9:V=VM*.447:IF V<1.8 THEN V=1.8
  370 XK=(SQR(V*100)-V+10.5)*(33-TC)
  380 TE=33-XK/22.116:TE=TE*9/5+32
  390 PRINT
  400 PRINT "Air temperature ";TF;" F and wind speed ";VM;" Mph"
  410 PRINT "Windchill temperature is ";TE
  420 PRINT
  430 PRINT "Approximate feeling: ";
  440 FOR I=1 TO NTH
  450   IF XK<TH(I) THEN PRINT M$(I):GOTO 480
  460 NEXT I
  470 PRINT M$(NTH)
  480 PRINT
  490 PRINT "<Hit SPACE to exit - any other key to continue>";
  500 A=GET:IF A=32 THEN CLS:END ELSE GOTO 290