#B
   .J
   NEW
   10 REM Eric the Caterpillar goes Munching! (C) C.R.Shelley
   20 REM by Chris Shelley,27 Old Forge Road,Layer-de-la-Haye,Colchester,Essex.CO2 0JT
   30 REM Z88 Users' Club number 0636
   40 REM
   50 *NAME Eric!
   60 P%=0
   70 VDU1,138,61,65,158,191,191,173,140,140,140,158
   80 VDU1,138,61,67,158,191,191,191,191,191,191,158
   90 VDU1,138,61,68,158,187,191,187,188,191,191,158
  100 VDU1,138,61,69,158,183,191,183,143,191,191,158
  110 VDU1,138,61,70,128,140,158,158,158,158,140,128
  120 VDU1,67
  130 N%=50:H%=100:S%=0
  160 CX=8:X1=0:X2=1:X3=2:X4=3:X5=4:X6=5:X7=6:X8=7
  170 CY=0:Y1=0:Y2=0:Y3=0:Y4=0:Y5=0:Y6=0:Y7=0:Y8=0
  180 DIR=2
  190 E$=CHR$(1)
  200 DIM S$(86,7)
  210 XZ$=CHR$(1)+CHR$(130)+CHR$(63)+CHR$(67):CAT$=XZ$+XZ$+XZ$+XZ$+XZ$+XZ$+CHR$(1)+CHR$(130)+"?"+"D"
  220 IF P%=0 THEN GOSUB 1270:P%=1
  230 F$=E$+"F"+E$+"B"
  240 CT=0
  250 GOSUB 1060
  260 PRINT TAB(CX,CY);:VDU1,130,63,68
  270 GOSUB 750
  280 PROCCMV
  290 IF I$<>"0" THEN DIR=VAL(I$)
  300 PROCMVE
  310 PRINT TAB(CX,CY);:IF DIR=1 OR DIR=3 THEN VDU1,130,63,69 ELSE VDU1,130,63,68
  320 PRINT TAB(X1,Y1);:VDU1,130,63,67
  330 PRINT TAB(X2,Y2);:VDU1,130,63,67
  340 PRINT TAB(X3,Y3);:VDU1,130,63,67
  350 PRINT TAB(X4,Y4);:VDU1,130,63,67
  360 PRINT TAB(X5,Y5);:VDU1,130,63,67
  370 PRINT TAB(X6,Y6);:VDU1,130,63,67
  380 PRINT TAB(X7,Y7);:VDU1,130,63,67
  390 PRINT TAB(X8,Y8);:VDU1,130,63,67
  400 IF S$(CX+1,CY+1)="T" THEN RS=8:GOTO 830
  410 IF S$(CX+1,CY+1)="W" THEN S$(CX+1,CY+1)=" ":S%=S%+5:CT=CT+1:IF CT+INT(N%/10)>N% THEN RS=11:GOTO 830
  420 IF CX=X1 AND CY=Y1 OR CX=X2 AND CY=Y2 OR CX=X3 AND CY=Y3 OR CX=X4 AND CY=Y4 OR CX=X5 AND CY=Y5 OR CX=X6 AND CY=Y6 OR CX=X7 AND CY=Y7 THEN RS=5:GOTO 830
  430 IF CX=X8 AND CY=Y8 THEN RS=5:GOTO 830
  440 PRINT TAB(86,2)F$;S%;F$
  450 GOTO 270
  460 BO=CT+RND(20)
  470 S%=S%+BO
  480 N%=N%+10
  490 CLS:PRINT TAB(39,0)E$;"B";BO:PRINT TAB(31,6)BO;E$"B":FOR A=1 TO 80
  500   PRINT TAB(A,3)" ";E$"R";E$;"BBONUS ";BO;" ";E$;"B";E$;"R"
  510   FOR B=1 TO 40:NEXT
  520 NEXT
  530 I$="P":DIR=2
  540 CLEAR:GOTO 160
  550 DEFPROCCMV
  560 IF DIR=1 AND I$="2" THEN RS=5:GOTO 830
  570 IF DIR=2 AND I$="1" THEN RS=5:GOTO 830
  580 IF DIR=3 AND I$="4" THEN RS=5:GOTO 830
  590 IF DIR=4 AND I$="3" THEN RS=5:GOTO 830
  600 ENDPROC
  610 DEFPROCMVE
  620 PRINT TAB(X1,Y1);" "
  630 X1=X2:X2=X3:X3=X4:X4=X5:X5=X6:X6=X7:X7=X8:X8=CX
  640 Y1=Y2:Y2=Y3:Y3=Y4:Y4=Y5:Y5=Y6:Y6=Y7:Y7=Y8:Y8=CY
  650 IF DIR=1 THEN CX=CX-1
  660 IF CX=-1 THEN RS=1:GOTO 830
  670 IF DIR=2 THEN CX=CX+1
  680 IF CX=80 THEN RS=2:GOTO 830
  690 IF DIR=3 THEN CY=CY-1
  700 IF CY=-1 THEN RS=3:GOTO 830
  710 IF DIR=4 THEN CY=CY+1
  720 IF CY=7 THEN RS=4:GOTO 830
  730 ENDPROC
  750 I$=INKEY$(10)
  760 IF I$="" OR I$<>"Q" AND I$<>"A" AND I$<>"O" AND I$<>"P" THEN I$="0"
  770 IF I$="Q" THEN I$="3"
  780 IF I$="A" THEN I$="4"
  790 IF I$="O" THEN I$="1"
  800 IF I$="P" THEN I$="2"
  810 IF I$="0" THEN I$=STR$(DIR):DR=DIR
  820 RETURN
  830 REM END
  840 IF RS=11 THEN GOTO 460
  850 VDU7
  860 CLS
  870 PRINT TAB(85,1);E$;"B";"SCORE"
  880 PRINT TAB(86,2);S%
  890 PRINT TAB(84,4);"HI-SCORE"
  900 PRINT TAB(86,5);H%
  910 VDU1,66
  920 PRINT TAB(70,6)CAT$
  930 PRINT TAB(30,0)F$;"** ** GAME OVER ** **";F$
  940 PRINT TAB(2,2)"The game is over because you hit ";
  950 IF RS=5 THEN PRINT "yourself."
  960 IF RS=1 OR RS=2 OR RS=3 OR RS=4 THEN PRINT "a boundary."
  970 IF RS=8 THEN PRINT "a mushroom."
  980 IF S%>H% THEN PRINT TAB(30,3)E$;"R";F$;"YOU BEAT THE HI-SCORE";F$;E$;"R":H%=S%
  990 PRINT TAB(2,4) "You scored ";S%
 1000 PRINT TAB(2,5)F$;"PRESS ANY KEY FOR ANOTHER GO.";F$
 1010 S%=0:N%=50
 1020 FOR A=1 TO 2000:NEXT
 1030 X$=GET$
 1040 H%=H%:CLEAR:GOTO 160
 1060 CLS
 1070 FOR A=1 TO N%
 1080   X=RND(80)-1
 1090   V=RND(80)-1
 1100   Y=RND(7)-1
 1110   W=RND(7)-1
 1120   IF S$(X+1,Y+1)="W" OR S$(V+1,W+1)="W" THEN GOTO 1080
 1130   PRINT TAB(X,Y);:VDU1,130,63,65
 1140   PRINT TAB(V,W);:VDU1,130,63,70
 1150   S$(X+1,Y+1)="T"
 1160   S$(V+1,W+1)="W"
 1170 NEXT
 1180 PRINT TAB(85,1);F$"SCORE"
 1190 PRINT TAB(86,2);S%
 1200 PRINT TAB(84,4);"HI-SCORE"
 1210 PRINT TAB(86,5);H%
 1220 VDU1,70,1,66
 1230 PRINT TAB(0,0);"          "
 1240 FOR A=0 TO 9:S$(A+1,1)=" ":NEXT A
 1250 RETURN
 1270 CLS
 1280 PRINT TAB(2,2);"You are Eric the Caterpillar ";E$"F";CAT$;E$;"F, and must walk around the garden eating the"
 1290 PRINT TAB(1,3);"seeds, ";E$"F";:VDU1,130,63,70:PRINT E$"F, but must avoid the deadly toadstools,";E$;"F";:VDU1,130,63,65:PRINT E$"F."
 1300 PRINT TAB(2,4);"Once you have eaten most of the seeds you will get a bonus and be able to progress"
 1310 PRINT TAB(1,5);"to the next garden, where there will be more seeds but more toadstools as well!"
 1320 PRINT TAB(2,6);"At all times you must beware not to run into the edge of the garden or yourself."
 1330 PRINT TAB(25,1);E$"B"E$"RERIC THE CATERPILLAR GOES MUNCHING!"E$"R"E$"B"
 1340 PRINT TAB(32,7);"PRESS ANY KEY TO PLAY"
 1350 PRINT TAB(89,2);"Q";TAB(88,3);"O+P";TAB(89,4);"A"
 1360 PRINT TAB(87,1);"Keys:"
 1370 X$=GET$
 1380 RETURN