* CardOpenBox.prg
* Create a new box
if CmB$="N"
  at 6,0 say "Enter the name of the card-box you want to create (leave blank to quit)        "
  let Box$="                                                                              "
  at 7,0 get Box$
  let Box$=trim(Box$)
  let Tmp=len(Box$)
  if Tmp<2
    let fModified=0
    return
  endif
  use
  let Tmp$=upper(Box$)
  if where(".DBF",Tmp$)=0
    let Box$=Box$+".dbf"
  endif
  let Tmp=len(Box$)-3
  let Ndx$=substr(Box$,1,Tmp)+"Ndx"
  create &Box$ from CardBase.def
  do AddGrid.prg
  index on Key$ to &Ndx$
  find "Index"
  return
endif
* Open an alternate box
let Box$=""
do while file(Box$)=0
  at 6,0 say "Enter the name of the card-box you want to use    (leave blank to quit)         "
  let Box$=Box$+"                                                                               "
  let Box$=substr(Box$,1,79)
  at 7,0 get Box$
  let Box$=trim(Box$)
  let Tmp=len(Box$)
  if Tmp<2
    let fModified=0
    return
  endif
  let Tmp$=upper(Box$)
  let Tmp=where(".DBF",Tmp$)
  if Tmp=0
    let Box$=Box$+".dbf"
  else
    let Box$=trim(Box$)
  endif
  if file(Box$)=0
    at 6,50 say Fl$+"Box does not exist!"+Fl$
  else
    at 6,50 say "                   "
    let Tmp=len(Box$)-3
    let Ndx$=substr(Box$,1,Tmp)+"Ndx"
    if file(Ndx$)=0
      at 6,50 say Fl$+"Box is not indexed!"+Fl$
      let Box$="!"+Box$
    else
      at 6,50 say "                   "
    endif
  endif
enddo
use &Box$ index &Ndx$
find "Index"
release Box$,Ndx$,Tmp$
return