You may sometimes wonder how it is that large organizations manage to generate manuals and documents which are virtually incomprehensible to anyone who does not already know everything they are talking about. The following program may shed some light on this; it will generate unlimited technical jargon, all of which will sound plausible and can be used to pad out any manual or conference paper. The phrases have been chosen to sound as impelling as possible, but of course the program can be altered to generate random outpourings on any particular subject.
The following paragraphs were produced by successive runs of the Buzz-Phrase generator:
Similarly, a constant flow of effective information necessitates that urgent consideration be applied to the greater fight-worthiness concept.
As a resultant implication, the characterisation of specific criteria requires considerable systems analysis and trade-off studies to arrive at the philosophy of commonality and standardisation.
In respect to specific goals, the fully integrated test program must utilise and be functionally interwoven with the structural design, based on system engineering concepts.
A particular feature of the program is that it prints the text neatly within the screen-width, without breaking words at the end of a line. This ensures that the Buzz-Phrases will be perfectly legible, even on a 40 or 32 character-per-line screen, and the routine could be useful with other text-output programs.
BBC Computer Version
In this version the required phrase is selected by doing a RESTORE to the required line. Note that because of this the program should not be renumbered.
1 REM ..Buzz-Phrases.. 10 W=40
Print out four parts of phrase, chosen at random. Wait for a key, then do another.
20 FORI=100 TO 400 STEP 100 30 RESTORE(10*RND(10)+I-10):READS$ 40 PROCPRETTY:NEXT I 50 PRINT"." 60 PRINT:I$=GET$:RUN
PROCPRETTY - Print as many words as will fit in width W, with 'return' between lines. Look for next space; concatenate "A" on string to get around INSTR bug. Put word into C$, remainder of string back into S$.
80 DEF PROCPRETTY REPEAT: A=INSTR(S$+"A'," ") 82 C$=LEFT$(S$,A): S$=MID$(S$,A+1) 84 IF A=0 C$=S$
If word in C$ will not fit on the line, do a 'return'. Then print word, until all of string finished.
86 IF COUNT+LEN(C$) >= W PRINT 88 PRINT C$;: UNTIL A=0 90 ENDPROC
Choices for first part.
100 DATA"In particular, " 110 DATA"On the other hand, " 120 DATA"However, " 130 DATA"Similarly, " 140 DATA"As a resultant implication, " 150 DATA"In this regard, " 160 DATA"Based on integral subsystem considerations, " 170 DATA"For example, " 180 DATA"Thus, " 190 DATA"In respect to specific goals, "
Choices for second part.
200 DATA"a large portion of the interface coordination communication " 210 DATA"a constant flow of effective information " 220 DATA"the characterisation of specific criteria " 230 DATA"initiation of critical subsystem development " 240 DATA"the fully integrated test program " 250 DATA"the product configuration baseline " 260 DATA"any associated supporting element " 270 DATA"the incorporation of additional mission constraints " 280 DATA"the independent functional principal " 290 DATA"a primary relationship between system and/or subsystem technologies "
Choices for third part.
300 DATA"must utilise and be functionally interwoven with " 310 DATA"maximizes the probability of project success and minimizes the cost and time required for " 320 DATA "adds specific performance limits to " 330 DATA"necessitates that urgent consideration be applied to " 340 DATA"requires considerable systems analysis and trade-off studies to arrive at " 350 DATA "is further compounded, when taking into account " 360 DATA"presents extremely interesting challenges to " 370 DATA"recognises the importance of other systems and the necessity for " 380 DATA"effects a significant implementation of " 390 DATA"adds overriding performance constraints to "
Choices for last part.
400 DATA"the sophisticated hardware" 410 DATA"the anticipated fourth generation equipment" 420 DATA"the subsystem compatibility testing" 430 DATA"the structural design, based on system engineering concepts" 440 DATA"the preliminary qualification limit" 450 DATA"the evolution of specifications over a given time period" 460 DATA"the philosophy of commonality and standardisation" 470 DATA"the greater fight-worthiness concept" 480 DATA"any discrete configuration mode" 490 DATA"the total system rationale"
Variables:
S$ - String for next part of phrase C$ - current word I - number of DATA statement W - screen width A - position of space in S$
Atom Version
The Atom does not have READ...DATA statements, so the strings are selected by assignment statements in subroutines, using a calculated GOSUB to selact the required subroutine.
1 REM ..BUZZ-PHRASES.. 10 DIM S(128);W=32
Print out four parts of phrase, chosen at random. Wait for a key, then do another.
20 FOR I=100 TO 400 STEP 100 30 GOSUB (10*(ABSRND%10)+I) 40 GOSUB p 50 LINK #FFE3; GOTO 20
p - Print as many words as will fit in width W, with 'return' between lines. Look for next space; current word pointed to by C.
80pC=S; DO A=0; DO A=A+1; UNTIL C?A=CH" "
Break word at space; if word will not fit print 'return'. Then print word, until all of string finished.
82 C?A=CH""; IF COUNT+LENC>=W PRINT ' 84 PRINT $C," ";C=C+LENC+1 86 UNTIL ?C=CH"" 88 NEXT; PRINT "."';RETURN
Choices for first part.
100 $S="IN PARTICULAR, "; RETURN 110 $S="ON THE OTHER HAND, "; RETURN 120 $S="HOWEVER, "; RETURN 130 $S="SIMILARLY, "; RETURN 140 $S="AS A RESULTANT IMPLICATION, "; RETURN 150 $S="IN THIS REGARD, "; RETURN 160 $S="BASED ON INTEGRAL SUBSYSTEM CONSIDERATIONS, "; RETURN 170 $S="FOR EXAMPLE, "; RETURN 180 $S="THUS, "; RETURN 190 $S="IN RESPECT TO SPECIFIC GOALS, "; RETURN
Choices for second part.
200 $S="A LARGE PORTION OF THE INTERFACE COORDINATION" 201 $S+LENS=" COMNUNICATION "; RETURN 210 $S="A CONSTANT FLOW OF EFFECTIVE INFORMATION "; RETURN 220 $S="THE CHARACTERISATION OF SPECIFIC CRITERIA "; RETURN 230 $S="INITIATION OF CRITICAL SUBSYSTEN DEVELOPMENT "; RETURN 240 $S="THE FULLY INTEGRATED TEST PROGRAM "; RETURN 250 $S="THE PRODUCT CONFIGURATION BASELINE "; RETURN 260 $S="ANY ASSOCIATED SUPPORTING ELEMENT "; RETURN 270 $S="THE INCORPORATION OF ADDITIONAL" 271 $S+LENS=" MISSION CONSTRAINTS "; RETURN 280 $S="THE INDEPENDENT FUNCTIONAL PRINCIPAL "; RETURN 290 $S="A PRIMARY RELATIONSHIP BETWEEN" 291 $S+LENS=" SYSTEM AND/OR SUBSYSTEM TECHNOLOGIES "; RETURN
Choices for third part.
300 $S="MUST UTILISE AND BE FUNCTIONALLY INTERWOVEN WITH "; RETURN 310 $S="MAXIMIZES THE PROBABILITY OF PROJECT SUCCESS AND" 311 $S+LENS=" MINIMIZES THE COST AND TIME REQUIRED FOR "; RETURN 320 $S="ADDS SPECIFIC PERFORMANCE LIMITS TO "; RETURN 330 $S="NECESSITATES THAT URGENT" 331 $S+LENS=" CONSIDERATION BE APPLIED TO "; RETURN 340 $S="REQUIRES CONSIDERABLE SYSTEMS ANALYSIS AND TRADE-OFF" 341 $S+LENS=" STUDIES TO ARRIVE AT "; RETURN 350 $S="IS FURTHER COMPOUNDED, WHEN TAKING INTO ACCOUNT "; RETURN 360 $S="PRESENTS EXTRENELY INTERESTING CHALLENGES TO "; RETURN 370 $S="RECOGNISES THE IMPORTANCE OF OTHER SYSTEMS AND THE" 371 $S+LENS=" NECESSITY FOR "; RETURN 380 $S="EFFECTS A SIGNIFICANT IMPLEMENTATION OF "; RETURN 390 $S="ADDS OVERRIDING PERFORMANCE CONSTRAINTS TO "; RETURN
Choices for last part.
400 $S="THE SOPHISTICATED HARDWARE "; RETURN 410 $S="THE ANTICIPATED FOURTH GENERATION EQUIPMENT "; RETURN 420 $S="THE SUBSYSTEM COMPATIBILITY TESTING "; RETURN 430 $S="THE STRUCTURAL DESIGN, BASED ON SYSTEM ENGINEERING" 431 $S+LENS=" CONCEPTS "; RETURN 440 $S="THE PRELIMINARY QUALIFICATION LIMIT "; RETURN 450 $S="THE EVOLUTION OF SPECIFICATIONS OVER A GIVEN TIME" 451 $S+LENS=" PERIOD "; RETURN 460 $S="THE PHILOSOPHY OF COMMONALITY AND" 461 S+LENS=" STANDARDISATION "; RETURN 470 $S="THE GREATER FIGHT-WORTHINESS CONCEPT "; RETURN 480 $S="ANY DISCRETE CONFIGURATION MODE "; RETURN 490 $S="THE TOTAL SYSTEM RATIONALE "; RETURN
Variables:
A - Pointer to space C - Current part of phrase I - Random number W - Screen width S - Phrase string